aboutsummaryrefslogtreecommitdiffstats
path: root/meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb
diff options
context:
space:
mode:
authorPaul Eggleton <paul.eggleton@linux.intel.com>2012-12-03 15:30:40 +0000
committerJoe MacDonald <joe.macdonald@windriver.com>2012-12-07 16:20:29 -0500
commitc71a08cea8477f69ee3bc511f1f14d99e09c0a49 (patch)
treefb3d95b89970d3620f2139c95513868f06fa86c5 /meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb
parent612119a4c2ea2fabbf4ffd655515b4abd5ec2283 (diff)
downloadmeta-openembedded-contrib-c71a08cea8477f69ee3bc511f1f14d99e09c0a49.tar.gz
meta-openembedded-contrib-c71a08cea8477f69ee3bc511f1f14d99e09c0a49.tar.bz2
meta-openembedded-contrib-c71a08cea8477f69ee3bc511f1f14d99e09c0a49.zip
ebtables: add from OE-Classic, update and tidy up
* Update to 2.0.10-4 * Handle hardcoded paths in initscript * Add LIC_FILES_CHKSUM * Set SUMMARY (which sets DESCRIPTION) * Drop PRIORITY * Minor formatting/ordering tweaks Based on a patch by Vladimir Redzhepoff <vladimir.redzhepoff@promwad.com> Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
Diffstat (limited to 'meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb')
-rw-r--r--meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb52
1 files changed, 52 insertions, 0 deletions
diff --git a/meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb b/meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb
new file mode 100644
index 0000000000..e3476daf0f
--- /dev/null
+++ b/meta-networking/recipes-filter/ebtables/ebtables_2.0.10-4.bb
@@ -0,0 +1,52 @@
+SUMMARY = "Utility for basic Ethernet frame filtering on a Linux bridge, MAC NAT and brouting."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=53b4a999993871a28ab1488fdbd2e73e"
+SECTION = "console/network"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/ebtables/ebtables-v${PV}.tar.gz \
+ file://installnonroot.patch \
+ file://01debian_defaultconfig.patch \
+ file://ebtables.init \
+ "
+
+SRC_URI[md5sum] = "506742a3d44b9925955425a659c1a8d0"
+SRC_URI[sha256sum] = "dc6f7b484f207dc712bfca81645f45120cb6aee3380e77a1771e9c34a9a4455d"
+
+S = "${WORKDIR}/ebtables-v${PV}"
+
+inherit update-rc.d
+
+EXTRA_OEMAKE = " \
+ BINDIR=${base_sbindir} \
+ MANDIR=${mandir} \
+ ETHERTYPESPATH=${sysconfdir} \
+ INITDIR=${sysconfdir}/init.d \
+ SYSCONFIGDIR=${sysconfdir}/default \
+ LIBDIR=${base_libdir}/ebtables \
+ 'CC=${CC}' \
+ 'CFLAGS=${CFLAGS}' \
+ 'LDFLAGS=${LDFLAGS} -Wl,--no-as-needed' \
+ 'LD=${LD}' \
+ "
+
+do_install () {
+ install -d ${D}${sysconfdir}/init.d
+ install -d ${D}${sysconfdir}/default
+ install -d ${D}${sysconfdir}/ebtables
+ oe_runmake DESTDIR='${D}' install
+ install -m 0755 ${WORKDIR}/ebtables.init ${D}/${sysconfdir}/init.d/ebtables
+ mv ${D}${sysconfdir}/default/ebtables-config ${D}${sysconfdir}/default/ebtables
+
+ # Fix hardcoded paths in scripts
+ sed -i 's!/sbin/!${base_sbindir}/!g' ${D}/${sysconfdir}/init.d/ebtables
+ sed -i 's!/etc/!${sysconfdir}/!g' ${D}/${sysconfdir}/init.d/ebtables
+}
+
+CONFFILES_${PN} += "${sysconfdir}/default/ebtables"
+
+INITSCRIPT_NAME = "ebtables"
+INITSCRIPT_PARAMS = "start 41 S . stop 41 6 ."
+
+FILES_${PN}-dbg += "${base_libdir}/ebtables/.debug"
+FILES_${PN} += "${base_libdir}/ebtables/*.so"