zsh: Change from 4.3.17 to 5.0.0, which is the latest stable release. Also change the mirror from the zsh ftp server, which is really slow and unstable, to a sourceforce mirror.

The reason for removing the 4.3.17 recipe is that it used the ftp mirror, which
has removed the 4.3.17 tarbal used.

Signed-off-by: Martin Ertsaas <mertsas@cisco.com>
Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>

1 files changed, 55 insertions, 0 deletions

diff --git a/meta-oe/recipes-extended/zsh/zsh.inc b/meta-oe/recipes-extended/zsh/zsh.inc
new file mode 100644
index 0000000000..cacce9140c
--- /dev/null
+++ b/meta-oe/recipes-extended/zsh/zsh.inc
@@ -0,0 +1,55 @@
+DESCRIPTION = "UNIX Shell similar to the Korn shell"
+HOMEPAGE="http://www.zsh.org"
+SECTION = "base/shell"
+
+PR = "r0"
+
+LICENSE = "ZSH"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=ad234d4b46db63491c4a9789da4fb341"
+
+DEPENDS = "ncurses bison-native"
+
+SRC_URI = "http://downloads.sourceforge.net/project/${BPN}/${BPN}/${PV}/${BPN}-${PV}.tar.gz"
+
+inherit autotools gettext update-alternatives
+
+EXTRA_OECONF = " \
+    --bindir=${base_bindir} \
+    --enable-etcdir=${sysconfdir} \
+    --enable-fndir=${datadir}/${PN}/${PV}/functions \
+    --enable-site-fndir=${datadir}/${PN}/site-functions \
+    --with-term-lib='ncursesw ncurses' \
+    --with-tcsetpgrp \
+    --enable-cap \
+    --enable-multibyte \
+    --disable-gdbm \
+    --disable-dynamic \
+    zsh_cv_shared_environ=yes \
+    "
+
+ALTERNATIVE_${PN} = "sh"
+ALTERNATIVE_LINK_NAME[sh] = "${base_bindir}/sh"
+ALTERNATIVE_TARGET[sh] = "${base_bindir}/${BPN}"
+ALTERNATIVE_PRIORITY = "100"
+
+export AUTOHEADER = "true"
+
+do_configure () {
+    oe_runconf
+}
+
+do_install_append () {
+    rm -fr ${D}/usr/share
+}
+
+pkg_postinst_${PN} () {
+    touch $D${sysconfdir}/shells
+    grep -q "bin/zsh" $D${sysconfdir}/shells || echo /bin/zsh >> $D${sysconfdir}/shells
+    grep -q "bin/sh" $D${sysconfdir}/shells || echo /bin/sh >> $D${sysconfdir}/shells
+}
+
+FILES_${PN}-dbg += "\
+    ${libdir}/${PN}/${PV}/${PN}/.debug/*.so \
+    ${libdir}/${PN}/${PV}/${PN}/db/.debug/*.so \
+    ${libdir}/${PN}/${PV}/${PN}/net/.debug/*.so \
+    "