3 files changed, 54 insertions, 0 deletions
diff --git a/meta-oe/recipes-support/gsoap/gsoap-native_2.8.12.bb b/meta-oe/recipes-support/gsoap/gsoap-native_2.8.12.bb
new file mode 100644
index 0000000000..46fabbbb47
--- /dev/null
+++ b/meta-oe/recipes-support/gsoap/gsoap-native_2.8.12.bb
@@ -0,0 +1,14 @@
+require gsoap_${PV}.inc
+
+DEPENDS = ""
+EXTRA_OEMAKE = ""
+
+inherit native
+
+do_install() {
+    oe_runmake DESTDIR=${D} BINDIR=${D}${bindir} install
+}
+
+
+SRC_URI[md5sum] = "5700d26fc6fe3073d038349e19c3640d"
+SRC_URI[sha256sum] = "51eef118544fa846f4d2dea2eedf91c84c46a1abeafc5eee3dcff783f4015a00"
diff --git a/meta-oe/recipes-support/gsoap/gsoap_2.8.12.bb b/meta-oe/recipes-support/gsoap/gsoap_2.8.12.bb
new file mode 100644
index 0000000000..5db2e61e54
--- /dev/null
+++ b/meta-oe/recipes-support/gsoap/gsoap_2.8.12.bb
@@ -0,0 +1,17 @@
+require gsoap_${PV}.inc
+
+DEPENDS = "gsoap-native openssl"
+
+do_install_append() {
+   install -d ${D}${libdir}
+   for lib in libgsoapssl libgsoapssl++ libgsoap libgsoapck++ libgsoap++ libgsoapck
+   do
+       oe_libinstall -C gsoap $lib ${D}${libdir}
+   done
+}
+
+FILES_${PN} = "${bindir}/wsdl2h ${bindir}/soapcpp2"
+FILES_${PN} += "${datadir}"
+
+SRC_URI[md5sum] = "5700d26fc6fe3073d038349e19c3640d"
+SRC_URI[sha256sum] = "51eef118544fa846f4d2dea2eedf91c84c46a1abeafc5eee3dcff783f4015a00"
diff --git a/meta-oe/recipes-support/gsoap/gsoap_2.8.12.inc b/meta-oe/recipes-support/gsoap/gsoap_2.8.12.inc
new file mode 100644
index 0000000000..30cf9a6d41
--- /dev/null
+++ b/meta-oe/recipes-support/gsoap/gsoap_2.8.12.inc
@@ -0,0 +1,23 @@
+DESCRIPTION = "The gSOAP toolkit provides a unique SOAP-to-C/C++ language binding \
+for the development of SOAP Web Services and clients."
+SECTION = "devel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b338b08b1b61e028e0f399a4de25e58f"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/gsoap2/gsoap_${PV}.zip \
+        "
+
+inherit autotools
+
+PR = "r1"
+
+S = "${WORKDIR}/gsoap-2.8"
+
+FILES_${PN}-dev = "${includedir}"
+RRECOMMENDS_${PN}-dev = "${PN}-staticdev"
+
+FILES_${PN}-staticdev = "${libdir}"
+
+PARALLEL_MAKE = ""
+
+EXTRA_OEMAKE = "SOAP=${STAGING_BINDIR_NATIVE}/soapcpp2"