aboutsummaryrefslogtreecommitdiffstats
path: root/meta-perl/recipes-perl/libnet/libnet-libidn-perl_0.12.bb
blob: 42b213dbdd4f05c5d3339957724f706bff54b7bc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
SUMMARY = "Net::LibIDN - Perl bindings for GNU Libidn"
DESCRIPTION = "\
Provides bindings for GNU Libidn, a C library for handling Internationalized \
Domain Names according to IDNA (RFC 3490), in a way very much inspired by \
Turbo Fredriksson's PHP-IDN. \
"
SECTION = "libs"
LICENSE = "Artistic-1.0 | GPLv1+"
HOMEPAGE = "http://search.cpan.org/dist/Net-LibIDN/"
DEPENDS += "libidn"
# We must need eglibc-gconvs to enable charset related functions, 
# such as Net::LibIDN::idn_to_ascii().
RDEPENDS_${PN} += "eglibc-gconvs"

SRC_URI = "http://search.cpan.org/CPAN/authors/id/T/TH/THOR/Net-LibIDN-${PV}.tar.gz"
SRC_URI[md5sum] = "c3e4de2065009d67bcb1df0afb473e12"
SRC_URI[sha256sum] = "2f8acc9442b3866ec7dc63cd449fc693ae3e930d5d3e5e9430fbb6f393bdbb17"

SRC_URI += "file://libidn-wr-cross-compile.patch"

LIC_FILES_CHKSUM = "file://README;beginline=42;endline=92;md5=3374ea0369ca3ead6047520477a43147"

S = "${WORKDIR}/Net-LibIDN-${PV}"

EXTRA_CPANFLAGS = "--with-libidn=${STAGING_LIBDIR} --with-libidn-inc=${STAGING_INCDIR} --compiler='${CC}'"
EXTRA_CPANFLAGS += "--disable-tld"

inherit cpan

FILES_${PN}-dbg += "${libdir}/perl/vendor_perl/*/auto/Net/LibIDN/.debug/"

do_configure_prepend() {
	rm -rf ${S}/.pc/
}