From 2ea8d7f54a061e902657c4f8ea1f7f7c25c6c4e1 Mon Sep 17 00:00:00 2001
From: Armin Kuster <akuster808@gmail.com>
Date: Sun, 18 Sep 2016 15:10:45 -0700
Subject: wireshark: update package to 1.12.13 for security fixes.

Fix build issue when X11 not defined.

Security fixes included in updating to this version:
CVE-2016-6511 CVE-2016-6510 CVE-2016-6509 CVE-2016-6508
CVE-2016-6507 CVE-2016-6506 CVE-2016-6505 CVE-2016-6504
CVE-2016-5359 CVE-2016-5357 CVE-2016-5356 CVE-2016-5355
CVE-2016-5354 CVE-2016-5353 CVE-2016-5351 CVE-2016-5350
CVE-2016-4421 CVE-2016-4418 CVE-2016-4417 CVE-2016-4085
CVE-2016-4082 CVE-2016-4081 CVE-2016-4080 CVE-2016-4079
CVE-2016-4078 CVE-2016-4006 CVE-2016-2532 CVE-2016-2531
CVE-2016-2530 CVE-2016-2523 CVE-2016-2521 CVE-2015-8733
CVE-2015-8732 CVE-2015-8731 CVE-2015-8730 CVE-2015-8729
CVE-2015-8728 CVE-2015-8727 CVE-2015-8726 CVE-2015-8725
CVE-2015-8724 CVE-2015-8723 CVE-2015-8722 CVE-2015-8721
CVE-2015-8720 CVE-2015-8719 CVE-2015-8718 CVE-2015-8717
CVE-2015-8716 CVE-2015-8715

Signed-off-by: Armin Kuster <akuster808@gmail.com>
---
 .../recipes-support/wireshark/wireshark_1.12.13.bb | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 meta-networking/recipes-support/wireshark/wireshark_1.12.13.bb

(limited to 'meta-networking/recipes-support/wireshark/wireshark_1.12.13.bb')

diff --git a/meta-networking/recipes-support/wireshark/wireshark_1.12.13.bb b/meta-networking/recipes-support/wireshark/wireshark_1.12.13.bb
new file mode 100644
index 0000000000..708899b2ee
--- /dev/null
+++ b/meta-networking/recipes-support/wireshark/wireshark_1.12.13.bb
@@ -0,0 +1,55 @@
+DESCRIPTION = "wireshark - a popular network protocol analyzer"
+HOMEPAGE = "http://www.wireshark.org"
+SECTION = "net"
+LICENSE = "GPL-2.0"
+LIC_FILES_CHKSUM = "file://README.linux;md5=631e077455b7972172eb149195e065b0"
+
+DEPENDS = "perl-native pcre expat glib-2.0 sbc"
+
+SRC_URI = "https://2.na.dl.wireshark.org/src/all-versions/${BP}.tar.bz2"
+
+PE = "1"
+
+SRC_URI[md5sum] = "15af85adc8ba83e6e996e13a55df4fb0"
+SRC_URI[sha256sum] = "7836cdaabd056ab4c9dd19cf0c791f11d980d0f6037542476034f2b7bdcf5d5b"
+
+inherit autotools pkgconfig
+
+ARM_INSTRUCTION_SET = "arm"
+
+PACKAGECONFIG ?= "libpcap gnutls libnl libcap"
+PACKAGECONFIG += " ${@bb.utils.contains("DISTRO_FEATURES", "x11", "gtk2  graphics", "", d)}"
+PACKAGECONFIG += " ${@bb.utils.contains("DISTRO_FEATURES", "opengl", "gtk3  graphics", "", d)}"
+PACKAGECONFIG += " ${@bb.utils.contains("DISTRO_FEATURES", "ipv6", "ipv6", "", d)}"
+
+PACKAGECONFIG[libcap] = "--with-libcap=${STAGING_LIBDIR}, --with-libcap=no --enable-pcap-ng-default , libcap"
+PACKAGECONFIG[libpcap] = "--with-pcap=${STAGING_LIBDIR} --with-pcap-remote, --with-pcap=no --enable-pcap-ng-default  , libpcap"
+PACKAGECONFIG[libsmi] = "--with-libsmi=yes, --with-libsmi=no, libsmi"
+PACKAGECONFIG[libnl] = "--with-libnl=yes, --with-libnl=no, libnl"
+PACKAGECONFIG[portaudio] = "--with-portaudio=yes, --with-portaudio=no, portaudio-v19"
+PACKAGECONFIG[gtk2] = "--with-gtk2=yes, --with-gtk2=no, gtk+"
+PACKAGECONFIG[gtk3] = "--with-gtk3=yes, --with-gtk3=no, gtk+3"
+PACKAGECONFIG[graphics] = "--enable-wireshark, --disable-wireshark,"
+PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
+PACKAGECONFIG[gnutls] = "--with-gnutls=yes, --with-gnutls=no, gnutls"
+PACKAGECONFIG[gcrypt] = "--with-gcrypt=yes, --with-gcrypt=no, libgcrypt"
+PACKAGECONFIG[ssl] = "--with-ssl=yes, --with-ssl=no, openssl"
+PACKAGECONFIG[krb5] = "--with-krb5=yes, --with-krb5=no, krb5"
+PACKAGECONFIG[lua] = "--with-lua=yes, --with-lua=no, lua"
+PACKAGECONFIG[zlib] = "--with-zlib=yes, --with-zlib=no, zlib"
+PACKAGECONFIG[geoip] = "--with-geoip=yes, --with-geoip=no, geoip"
+PACKAGECONFIG[plugins] = "--with-plugins=yes, --with-plugins=no"
+
+# these next two options require addional layers
+PACKAGECONFIG[adns] = "--with-adns=yes, --with-adns=no, adns"
+PACKAGECONFIG[c-ares] = "--with-c-ares=yes, --with-c-ares=no, c-ares"
+
+EXTRA_OECONF += "--with-qt=no --enable-usr-local=no --enable-tshark --enable-rawshark"
+
+do_configure_prepend() {
+    # force to use fallback 
+    sed -i -e '/^glib_prefix/s/=.*$/=""/' ${S}/aclocal-flags
+}
+
+ALLOW_EMPTY_${PN} = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-- 
cgit 1.2.3-korg