blob: 4377e88e474eb9564e1b27747927d603939e1b32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
SUMMARY = "Free and Open On-Chip Debugging, In-System Programming and Boundary-Scan Testing"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
DEPENDS = "libusb-compat libftdi"
RDEPENDS_${PN} = "libusb1"
SRC_URI = " \
git://repo.or.cz/openocd.git;protocol=http;name=openocd \
git://repo.or.cz/r/git2cl.git;protocol=http;destsuffix=tools/git2cl;name=git2cl \
git://repo.or.cz/r/jimtcl.git;protocol=http;destsuffix=git/jimtcl;name=jimtcl \
git://repo.or.cz/r/libjaylink.git;protocol=http;destsuffix=git/src/jtag/drivers/libjaylink;name=libjaylink \
file://0001-Fix-libusb-1.0.22-deprecated-libusb_set_debug-with-l.patch \
"
SRCREV_FORMAT = "openocd"
SRCREV_openocd = "cdf1e826eb23c29de1019ce64125f644f01b0afe"
SRCREV_git2cl = "8373c9f74993e218a08819cbcdbab3f3564bbeba"
SRCREV_jimtcl = "a9bf5975fd0f89974d689a2d9ebd0873c8d64787"
SRCREV_libjaylink = "8645845c1abebd004e991ba9a7f808f4fd0c608b"
PV = "0.10+gitr${SRCPV}"
S = "${WORKDIR}/git"
inherit pkgconfig autotools-brokensep gettext
BBCLASSEXTEND += "nativesdk"
EXTRA_OECONF = "--enable-ftdi --disable-doxygen-html"
do_configure() {
./bootstrap nosubmodule
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/jimtcl/autosetup
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/jimtcl/autosetup
oe_runconf ${EXTRA_OECONF}
}
do_install() {
oe_runmake DESTDIR=${D} install
if [ -e "${D}${infodir}" ]; then
rm -Rf ${D}${infodir}
fi
if [ -e "${D}${mandir}" ]; then
rm -Rf ${D}${mandir}
fi
if [ -e "${D}${bindir}/.debug" ]; then
rm -Rf ${D}${bindir}/.debug
fi
}
FILES_${PN} = " \
${datadir}/openocd/* \
${bindir}/openocd \
"
PACKAGECONFIG[sysfsgpio] = "--enable-sysfsgpio,--disable-sysfsgpio"
PACKAGECONFIG ??= "sysfsgpio"
|
