summaryrefslogtreecommitdiffstats
path: root/meta/classes/mime.bbclass
blob: dcdc27a74ca58f2034c45ffc6219faecb5878a44 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
DEPENDS += "shared-mime-info-native shared-mime-info"

EXTRA_OECONF += "--disable-update-mimedb"

mime_postinst() {
if [ "$1" = configure ]; then
	UPDATEMIMEDB=`which update-mime-database`
	if [ -x "$UPDATEMIMEDB" ] ; then
		echo "Updating MIME database... this may take a while."
		$UPDATEMIMEDB $D${datadir}/mime
	else
		echo "Missing update-mime-database, update of mime database failed!"
		exit 1
	fi
fi
}

mime_postrm() {
if [ "$1" = remove ] || [ "$1" = upgrade ]; then
	UPDATEMIMEDB=`which update-mime-database`
	if [ -x "$UPDATEMIMEDB" ] ; then
		echo "Updating MIME database... this may take a while."
		$UPDATEMIMEDB $D${datadir}/mime
	else
		echo "Missing update-mime-database, update of mime database failed!"
		exit 1
	fi
fi
}

python populate_packages_append () {
	import re
	packages = d.getVar('PACKAGES', True).split()
	pkgdest =  d.getVar('PKGDEST', True)

	for pkg in packages:
		mime_dir = '%s/%s/usr/share/mime/packages' % (pkgdest, pkg)
		mimes = []
		mime_re = re.compile(".*\.xml$")
		if os.path.exists(mime_dir):
			for f in os.listdir(mime_dir):
				if mime_re.match(f):
					mimes.append(f)
		if mimes:
			bb.note("adding mime postinst and postrm scripts to %s" % pkg)
			postinst = d.getVar('pkg_postinst_%s' % pkg, True) or d.getVar('pkg_postinst', True)
			if not postinst:
				postinst = '#!/bin/sh\n'
			postinst += d.getVar('mime_postinst', True)
			d.setVar('pkg_postinst_%s' % pkg, postinst)
			postrm = d.getVar('pkg_postrm_%s' % pkg, True) or d.getVar('pkg_postrm', True)
			if not postrm:
				postrm = '#!/bin/sh\n'
			postrm += d.getVar('mime_postrm', True)
			d.setVar('pkg_postrm_%s' % pkg, postrm)
			bb.note("adding shared-mime-info-data dependency to %s" % pkg)
			rdepends = explode_deps(d.getVar('RDEPENDS_' + pkg, False) or d.getVar('RDEPENDS', False)) or ""
			rdepends.append("shared-mime-info-data")
			d.setVar('RDEPENDS_' + pkg, " " + " ".join(rdepends))
}