summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/packagegroups/packagegroup-cross-canadian.bb
blob: 3b430c081484b9bd25e60ae9d8dfe6994cf04290 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
SUMMARY = "Host SDK package for cross canadian toolchain"
PN = "packagegroup-cross-canadian-${MACHINE}"

inherit cross-canadian packagegroup

PACKAGEGROUP_DISABLE_COMPLEMENTARY = "1"

# Use indirection to stop these being expanded prematurely
BINUTILS = "binutils-cross-canadian-${TRANSLATED_TARGET_ARCH}"
GCC = "gcc-cross-canadian-${TRANSLATED_TARGET_ARCH}"
GDB = "gdb-cross-canadian-${TRANSLATED_TARGET_ARCH}"

RDEPENDS_${PN} = "\
    ${@all_multilib_tune_values(d, 'BINUTILS')} \
    ${@all_multilib_tune_values(d, 'GCC')} \
    ${@all_multilib_tune_values(d, 'GDB')} \
    meta-environment-${MACHINE} \
    "

# When TUNE_ARCH changes but MACHINE does not (for example when a machine definition is updated), 
# cross-canadian.bbclass prevents variable dependency propagation to TRANSLATED_TARGET_ARCH
# This will result in erroneous reuse of previous sstate packages. The following line
# establishes a direct dependency instead.
do_package[vardeps] += "TUNE_ARCH"