rename packages/ to recipes/ per earlier agreement

See links below for more details:
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21326
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21816

Signed-off-by: Denys Dmytriyenko <denis@denix.org>
Acked-by: Mike Westerhof <mwester@dls.net>
Acked-by: Philip Balister <philip@balister.org>
Acked-by: Khem Raj <raj.khem@gmail.com>
Acked-by: Marcin Juszkiewicz <hrw@openembedded.org>
Acked-by: Koen Kooi <koen@openembedded.org>
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>

1 files changed, 0 insertions, 137 deletions

diff --git a/packages/binutils/binutils.inc b/packages/binutils/binutils.inc
deleted file mode 100644
index 49d3aeaa3c..0000000000
--- a/packages/binutils/binutils.inc
+++ /dev/null
@@ -1,137 +0,0 @@
-DESCRIPTION = "A GNU collection of binary utilities"
-HOMEPAGE = "http://www.gnu.org/software/binutils/"
-SECTION = "devel"
-LICENSE = "GPL"
-
-inherit autotools gettext
-
-PACKAGES += "${PN}-symlinks"
-
-FILES_${PN} = " \
-	${bindir}/${TARGET_PREFIX}* \
-	${libdir}/lib*-*.so \
-	${prefix}/${TARGET_SYS}/bin/*"
-
-FILES_${PN}-dev = " \
-	${includedir} \
-	${libdir}/*.a \
-	${libdir}/*.la \
-	${libdir}/libbfd.so \
-	${libdir}/libopcodes.so"
-
-FILES_${PN}-symlinks = " \
-	${bindir}/addr2line \
-	${bindir}/as \
-	${bindir}/c++filt \
-	${bindir}/gprof \
-	${bindir}/ld \
-	${bindir}/nm \
-	${bindir}/objcopy \
-	${bindir}/objdump \
-	${bindir}/ranlib \
-	${bindir}/readelf \
-	${bindir}/size \
-	${bindir}/strip"
-
-S = "${WORKDIR}/binutils-${PV}"
-B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
-
-EXTRA_OECONF = "--program-prefix=${TARGET_PREFIX} \
-		--enable-shared"
-
-# This is necessary due to a bug in the binutils Makefiles
-EXTRA_OEMAKE = "configure-build-libiberty all"
-
-export AR = "${HOST_PREFIX}ar"
-export AS = "${HOST_PREFIX}as"
-export LD = "${HOST_PREFIX}ld"
-export NM = "${HOST_PREFIX}nm"
-export RANLIB = "${HOST_PREFIX}ranlib"
-export OBJCOPY = "${HOST_PREFIX}objcopy"
-export OBJDUMP = "${HOST_PREFIX}objdump"
-
-export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
-export AS_FOR_TARGET = "${TARGET_PREFIX}as"
-export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
-export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
-export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
-
-export CC_FOR_HOST = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
-export CXX_FOR_HOST = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
-
-export CC_FOR_BUILD = "${BUILD_CC}"
-export CPP_FOR_BUILD = "${BUILD_CPP}"
-export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
-
-export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
-
-do_configure () {
-	(cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
-
-        # Fix for issues when system's texinfo version >= 4.10
-        # (See https://bugzilla.redhat.com/show_bug.cgi?id=345621)
-        sed -i -e "s@egrep 'texinfo.*'@egrep 'texinfo[^0-9]*([1-3][0-9]|4\.[4-9]|4.[1-9][0-9]+|[5-9])'@" '${S}/configure'
-
-	oe_runconf
-#
-# must prime config.cache to ensure the build of libiberty
-#
-        mkdir -p ${B}/build-${BUILD_SYS}
-	for i in ${CONFIG_SITE}; do
-	    cat $i >> ${B}/build-${BUILD_SYS}/config.cache
-	done
-}
-
-do_stage () {
-	oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
-	oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
-	oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
-	install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
-	install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
-	install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
-	install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
-	install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
-	install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
-}
-
-do_install () {
-	autotools_do_install
-
-	# We don't really need these, so we'll remove them...
-	rm -rf ${D}${libdir}/ldscripts
-
-	# Fix the /usr/${TARGET_SYS}/bin/* links
-	for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
-		rm -f $l
-		ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
-			| tr -s / \
-			| sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
-	done
-
-	# Install the libiberty header
-	install -d ${D}${includedir}
-	install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
-	install -m 644 ${S}/include/libiberty.h ${D}${includedir}
-
-	cd ${D}${bindir}
-
-	# Symlinks for ease of running these on the native target
-	for p in ${TARGET_SYS}-* ; do
-		ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
-	done
-
-	rm ${D}${bindir}/ar ${D}${bindir}/strings
-}
-
-
-pkg_postinst_${PN}-symlinks () {
-	update-alternatives --install ${bindir}/ar ar ${TARGET_SYS}-ar 100
-	update-alternatives --install ${bindir}/strings strings ${TARGET_SYS}-strings 100
-}
-
-
-pkg_prerm_${PN}-symlinks () {
-	update-alternatives --remove ar ${TARGET_SYS}-ar
-	update-alternatives --remove strings ${TARGET_SYS}-strings
-}
-