aboutsummaryrefslogtreecommitdiffstats
path: root/recipes/bluez/bluez4.inc
diff options
context:
space:
mode:
authorRolf Leggewie <oe-devel@rolf.leggewie.biz>2009-06-23 14:28:51 +0200
committerRolf Leggewie <oe-devel@rolf.leggewie.biz>2009-06-23 14:32:53 +0200
commit78ca80197a7acfed9f2259b053262a563b34b96b (patch)
tree1f675b9ba88b9e7310c7a072ef554f018107bc5d /recipes/bluez/bluez4.inc
parent1b9b11cdb9d9d4788ecd303fc6589c337828598b (diff)
downloadopenembedded-78ca80197a7acfed9f2259b053262a563b34b96b.tar.gz
openembedded-78ca80197a7acfed9f2259b053262a563b34b96b.tar.bz2
openembedded-78ca80197a7acfed9f2259b053262a563b34b96b.zip
bluez4: poor man's unification
Diffstat (limited to 'recipes/bluez/bluez4.inc')
-rw-r--r--recipes/bluez/bluez4.inc68
1 files changed, 68 insertions, 0 deletions
diff --git a/recipes/bluez/bluez4.inc b/recipes/bluez/bluez4.inc
new file mode 100644
index 0000000000..f9a72a5345
--- /dev/null
+++ b/recipes/bluez/bluez4.inc
@@ -0,0 +1,68 @@
+DESCRIPTION = "Linux Bluetooth Stack Userland V4"
+SECTION = "libs"
+PRIORITY = "optional"
+DEPENDS = "gst-plugins-base alsa-lib libusb-compat dbus-glib"
+HOMEPAGE = "http://www.bluez.org"
+LICENSE = "GPL"
+INC_PR = "r1"
+
+# For angstrom we want this to replace at least bluez-libs
+PROVIDES_append_angstrom = " bluez-utils bluez-libs"
+
+SRC_URI = "\
+ http://www.kernel.org/pub/linux/bluetooth/bluez-${PV}.tar.gz \
+ file://fix-dfutool-usb-declaration-mismatch.patch;patch=1 \
+ file://sbc-thumb.patch;patch=1 \
+ file://bluetooth.conf \
+"
+S = "${WORKDIR}/bluez-${PV}"
+
+inherit autotools_stage update-rc.d
+AUTOTOOLS_STAGE_PKGCONFIG = "1"
+
+EXTRA_OECONF = "\
+ --enable-gstreamer \
+ --enable-alsa \
+ --enable-usb \
+ --enable-netlink \
+ --enable-tools \
+ --enable-bccmd \
+ --enable-hid2hci \
+ --enable-dfutool \
+ --enable-hidd \
+ --enable-pandd \
+ --enable-dund \
+ --disable-cups \
+ --enable-test \
+ --enable-manpages \
+ --enable-configfiles \
+ --enable-initscripts \
+ --disable-pcmciarules \
+"
+
+do_install_append() {
+ install -m 0644 ${S}/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
+ install -m 0644 ${S}/network/network.conf ${D}/${sysconfdir}/bluetooth/
+ install -m 0644 ${S}/input/input.conf ${D}/${sysconfdir}/bluetooth/
+ # at_console doesn't really work with the current state of OE, so punch some more holes so people can actually use BT
+ install -m 0644 ${WORKDIR}/bluetooth.conf ${D}/${sysconfdir}/dbus-1/system.d/
+}
+
+INITSCRIPT_NAME = "bluetooth"
+INITSCRIPT_PARAMS = "defaults 23 19"
+
+PACKAGES =+ "gst-plugin-bluez libasound-module-bluez"
+
+FILES_gst-plugin-bluez = "${libdir}/gstreamer-0.10/lib*.so"
+FILES_libasound-module-bluez = "${libdir}/alsa-lib/lib*.so"
+FILES_${PN} += "${libdir}/bluetooth/plugins/*.so"
+FILES_${PN}-dev += "\
+ ${libdir}/bluetooth/plugins/*.la \
+ ${libdir}/alsa-lib/*.la \
+ ${libdir}/gstreamer-0.10/*.la \
+"
+
+FILES_${PN}-dbg += "\
+ ${libdir}/bluetooth/plugins/.debug \
+ ${libdir}/*/.debug \
+"