navit: change to INC_PR, bump srcrev, split icons and config for navit_svn

* xpm stuff is updated maybe about 6 times a year, sources are updated
  few times every day
* with navit-icons in separate package we don't need to download 3,5MB
  package, every time we bump SRCREV because of software fix
* navit-icons SRCREV will be changed only if there is new icon needed
  for newer navit SRCREV
* big package was installed by opkg really slow
* provide 2 desktop icons one with Display blanking disabled ie for car
  navigation, second with only CPU requested ie if you're using navit on
  foot or bike and want longer battery life
* splitted configs are easier to modify, also provide better defaults for
  freerunner layout

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 51 insertions, 2 deletions

diff --git a/recipes/navit/navit_svn.bb b/recipes/navit/navit_svn.bb
index 833eb4714e..3323611210 100644
--- a/recipes/navit/navit_svn.bb
+++ b/recipes/navit/navit_svn.bb
@@ -1,12 +1,61 @@
 require navit.inc
 
-PV = "0.1.0+svnrev${SRCREV}"
-PR = "r2"
+PV = "0.1.0+svnr${SRCPV}"
+PR = "${INC_PR}.0"
 
 DEFAULT_PREFERENCE = "-1"
+DEFAULT_PREFERENCE_shr = "1"
 
 S = "${WORKDIR}/navit"
 
+# use espeak instead speechd
+RRECOMMENDS = "gpsd espeak flite"
+
+EXTRA_OECONF += "--enable-avoid-unaligned  --enable-svg2png-scaling-flag=32 --disable-speech-speech-dispatcher"
+
 SRC_URI = "svn://anonymous@navit.svn.sourceforge.net/svnroot/navit/trunk;module=navit;proto=https"
 
 EXTRA_AUTORECONF = " -I m4"
+
+FILES_${PN} += " ${datadir}/dbus-1/services/ "
+
+CONFFILES_${PN} += "${datadir}/navit/navit.default.xml \
+                    ${datadir}/navit/navit.xml \
+                    ${datadir}/navit/maps.xml \
+                    ${datadir}/navit/osd.xml \
+                    ${datadir}/navit/speech.xml \
+                   "
+
+SRC_URI += "file://navit.xml \
+            file://maps.xml \
+            file://osd.xml \
+            file://speech.xml \
+	   "
+
+#Second launcher for shr
+SRC_URI_append_shr = "file://navitD.desktop \
+                      file://navitD.png \
+                     "
+
+DEPENDS_append_shr = " gypsy"
+RDEPENDS_append_shr = " fsoraw"
+
+do_configure_prepend() {
+  #Remove xpm building, replaced by icons in own package
+  sed -i 's/\(.*SUBDIRS.*\) xpm\( \|$\)\(.*\)/\1\2\3/g' ${S}/navit/Makefile.am
+}
+
+do_install_append() {
+        #Use split config
+        mv ${D}${datadir}/navit/navit.xml ${D}${datadir}/navit/navit.default.xml
+        install -m 0644 ${WORKDIR}/navit.xml ${D}${datadir}/navit/navit.xml
+        install -m 0644 ${WORKDIR}/maps.xml ${D}${datadir}/navit/maps.xml
+        install -m 0644 ${WORKDIR}/osd.xml ${D}${datadir}/navit/osd.xml
+        install -m 0644 ${WORKDIR}/speech.xml ${D}${datadir}/navit/speech.xml
+}
+
+do_install_append_shr() {
+        #Install second launcher for shr
+        install -m 0644 ${WORKDIR}/navitD.desktop ${D}${datadir}/applications/
+        install -m 0644 ${WORKDIR}/navitD.png ${D}${datadir}/pixmaps/
+}