rename packages/ to recipes/ per earlier agreement

See links below for more details:
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21326
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21816

Signed-off-by: Denys Dmytriyenko <denis@denix.org>
Acked-by: Mike Westerhof <mwester@dls.net>
Acked-by: Philip Balister <philip@balister.org>
Acked-by: Khem Raj <raj.khem@gmail.com>
Acked-by: Marcin Juszkiewicz <hrw@openembedded.org>
Acked-by: Koen Kooi <koen@openembedded.org>
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>

1 files changed, 43 insertions, 0 deletions

diff --git a/recipes/xorg-driver/xorg-driver-common.inc b/recipes/xorg-driver/xorg-driver-common.inc
new file mode 100644
index 0000000000..0f24dd5e30
--- /dev/null
+++ b/recipes/xorg-driver/xorg-driver-common.inc
@@ -0,0 +1,43 @@
+DESCRIPTION = "X driver"
+HOMEPAGE = "http://www.x.org"
+SECTION = "x11/drivers"
+LICENSE = "MIT-X"
+PR = "r2"
+
+DEPENDS = "randrproto xorg-server xproto"
+
+XORG_PN = "${PN}"
+SRC_URI = "${XORG_MIRROR}/individual/driver/${XORG_PN}-${PV}.tar.bz2"
+
+S = "${WORKDIR}/${XORG_PN}-${PV}"
+
+FILES_${PN} += " ${libdir}/xorg/modules"
+FILES_${PN}-dbg +=  "${libdir}/xorg/modules/*/.debug"
+
+inherit autotools pkgconfig
+
+do_stage() {
+	autotools_stage_all
+}
+
+# Another sucky behavor from Xorg configure scripts.
+# They use AC_CHECK_FILE to check for DRI headers. Yuck!
+# Of course this will blow up when cross compiling.
+
+do_configure_prepend() {
+	incdir=${layout_includedir}/xorg
+	for f in dri.h sarea.h dristruct.h exa.h damage.h xf86Module.h; do
+		path="$incdir/$f"
+		if [ -f "${STAGING_DIR_HOST}/$path" ]; then
+			p=`echo "$path" | sed 'y%*+%pp%;s%[^_[:alnum:]]%_%g'`
+			eval "export ac_cv_file_$p=yes"
+		fi
+	done
+}
+
+# FIXME: We don't want to include the libtool archives (*.la) from modules
+# directory, as they serve no useful purpose. Upstream should fix Makefile.am
+do_install_append() {
+	find ${D}${libdir}/xorg/modules -regex ".*\.la$" | xargs rm -f --
+}
+