11 files changed, 253 insertions, 0 deletions
diff --git a/packages/e17/e-utils_svn.bb b/packages/e17/e-utils_svn.bb
new file mode 100644
index 0000000000..f90a118cdf
--- /dev/null
+++ b/packages/e17/e-utils_svn.bb
@@ -0,0 +1,12 @@
+DESCRIPTION = "Enlightenment Window Manager Utilities"
+DEPENDS = "eet evas ecore edje esmart ewl engrave"
+LICENSE = "MIT BSD"
+PV = "0.0.0+svnr${SRCREV}"
+PR = "r1"
+
+inherit e
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk/OLD;module=e_utils;proto=http"
+S = "${WORKDIR}/e_utils"
+
+FILES_${PN} = "${bindir}/* ${libdir}/* ${datadir}"
diff --git a/packages/e17/e-wm_svn.bb b/packages/e17/e-wm_svn.bb
new file mode 100644
index 0000000000..7c3e950569
--- /dev/null
+++ b/packages/e17/e-wm_svn.bb
@@ -0,0 +1,70 @@
+DESCRIPTION = "The Enlightenment Window Mananger Version 17"
+DEPENDS = "eet evas ecore edje efreet edbus"
+LICENSE = "MIT BSD"
+PV = "0.16.999.043+svnr${SRCREV}"
+PR = "r11"
+
+inherit e update-alternatives
+
+SRC_URI = "\
+  svn://svn.enlightenment.org/svn/e/trunk;module=e;proto=http \
+  file://disable-e-cursor.patch;patch=1 \
+  file://enlightenment_start.oe \
+  file://applications.menu \
+"
+S = "${WORKDIR}/e"
+
+EXTRA_OECONF = "\
+  --with-edje-cc=${STAGING_BINDIR_NATIVE}/edje_cc \
+  --x-includes=${STAGING_INCDIR}/X11 \
+  --x-libraries=${STAGING_LIBDIR} \
+  --enable-simple-x11 \
+"
+
+do_configure_prepend() {
+	autopoint
+}
+
+do_stage() {
+    autotools_stage_all
+    for I in `find ${STAGING_LIBDIR}/enlightenment -name "*.la" -print`; do rm -f $I; done
+    for I in `find ${STAGING_LIBDIR}/enlightenment -name "*.a" -print`; do rm -f $I; done
+    for I in `find ${STAGING_LIBDIR_CROSS}/enlightenment -name "*.la" -print`; do rm -f $I; done
+    for I in `find ${STAGING_LIBDIR_CROSS}/enlightenment -name "*.a" -print`; do rm -f $I; done
+}
+
+do_install_append() {
+    # customising - should rather make this simple upstream
+    rm -rf ${D}${datadir}/enlightenment/data/backgrounds/*
+    rm -rf ${D}${datadir}/enlightenment/data/fonts/*
+    rm -rf ${D}${datadir}/enlightenment/data/other/*
+    install -m 755 ${WORKDIR}/enlightenment_start.oe ${D}/${bindir}
+    install -d ${D}/${sysconfdir}/xdg/menus
+    install -m 644 ${WORKDIR}/applications.menu ${D}/${sysconfdir}/xdg/menus/
+}
+
+RDEPENDS += "shared-mime-info mime-support"
+
+FILES_${PN} = "\
+  ${bindir}/* \
+  ${libdir}/enlightenment/modules/*/*.* \
+  ${libdir}/enlightenment/modules/*/*/* \
+  ${libdir}/enlightenment/preload/*.so \
+  ${datadir} \
+  ${sysconfdir} \
+"
+FILES_${PN}-dbg += "\
+  ${libdir}/enlightenment/modules/*/*/.debug/ \
+  ${libdir}/enlightenment/preload/.debug/ \
+"
+
+FILES_${PN}-dev += "\
+  ${libdir}/enlightenment/preload/*.?a \
+"
+
+CONFFILES_${PN} = "/etc/xdg/menus/applications.menu"
+
+ALTERNATIVE_PATH = "${bindir}/enlightenment_start.oe"
+ALTERNATIVE_NAME = "x-window-manager"
+ALTERNATIVE_LINK = "${bindir}/x-window-manager"
+ALTERNATIVE_PRIORITY = "16"
diff --git a/packages/e17/edje-editor_svn.bb b/packages/e17/edje-editor_svn.bb
new file mode 100644
index 0000000000..4cbbf19e9e
--- /dev/null
+++ b/packages/e17/edje-editor_svn.bb
@@ -0,0 +1,12 @@
+DESCRIPTION = "Edje-Editor is just that."
+LICENSE = "MIT BSD"
+DEPENDS = "etk"
+PV = "0.0.0+svnr${SRCREV}"
+PR = "r1"
+
+inherit e
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk;module=edje_editor;proto=http"
+S = "${WORKDIR}/edje_editor"
+
+FILES_${PN} = "${bindir}/* ${libdir}/* ${datadir} ${sysconfdir} ${sbindir}"
diff --git a/packages/e17/edje-viewer_svn.bb b/packages/e17/edje-viewer_svn.bb
new file mode 100644
index 0000000000..c9bbba783f
--- /dev/null
+++ b/packages/e17/edje-viewer_svn.bb
@@ -0,0 +1,13 @@
+DESCRIPTION = "Edje_Viewer is just that."
+DEPENDS = "etk"
+LICENSE = "MIT BSD"
+PV = "0.0.0+svnr${SRCREV}"
+PR = "r1"
+
+inherit e
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk;module=edje_viewer;proto=http \
+           file://no-minimal-size.patch;patch=1"
+S = "${WORKDIR}/edje_viewer"
+
+FILES_${PN} = "${bindir}/* ${libdir}/* ${datadir} ${sysconfdir} ${sbindir}"
diff --git a/packages/e17/enna_svn.bb b/packages/e17/enna_svn.bb
new file mode 100644
index 0000000000..6bfabbdee5
--- /dev/null
+++ b/packages/e17/enna_svn.bb
@@ -0,0 +1,16 @@
+DESCRIPTION = "Enna is a media center application based on EFL"
+LICENSE = "GPL"
+DEPENDS = "curl dbus eet evas edje ecore edbus emotion"
+DEPENDS += "libmusicbrainz lightmediascanner libxml2 taglib"
+SECTION = "x11/multimedia"
+PV = "0.2.0+svnr${SRCREV}"
+PR = "r1"
+
+inherit e
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk/MISC;module=enna;proto=http"
+S = "${WORKDIR}/enna"
+
+do_configure_prepend() {
+    autopoint
+}
diff --git a/packages/e17/examine_svn.bb b/packages/e17/examine_svn.bb
new file mode 100644
index 0000000000..223d29ca25
--- /dev/null
+++ b/packages/e17/examine_svn.bb
@@ -0,0 +1,13 @@
+DESCRIPTION = "Examine, the program configurator"
+LICENSE = "MIT BSD"
+DEPENDS = "ewl"
+PV = "0.0.1+svnr${SRCREV}"
+PR = "r1"
+
+SRCNAME = "examine"
+
+inherit e
+
+EXTRA_OECONF = "--with-edje-cc=${STAGING_BINDIR_NATIVE}/edje_cc"
+
+FILES_${PN} = "${bindir}/* ${libdir}/* ${datadir} ${sysconfdir} ${sbindir}"
diff --git a/packages/e17/exhibit_svn.bb b/packages/e17/exhibit_svn.bb
new file mode 100644
index 0000000000..6ec34d6ff9
--- /dev/null
+++ b/packages/e17/exhibit_svn.bb
@@ -0,0 +1,9 @@
+DESCRIPTION = "Exhibit is the ETK picture viewer"
+LICENSE = "MIT BSD"
+DEPENDS = "evas ecore epsilon edje eet etk efreet"
+PV = "0.1.1+svnr${SRCREV}"
+PR = "r1"
+
+SRCNAME = "exhibit"
+
+inherit e
diff --git a/packages/e17/expedite_svn.bb b/packages/e17/expedite_svn.bb
new file mode 100644
index 0000000000..2f3ef20e16
--- /dev/null
+++ b/packages/e17/expedite_svn.bb
@@ -0,0 +1,31 @@
+DESCRIPTION = "Expedite is a comprehensive benchmarking suite for Evas"
+DEPENDS = "eet evas"
+RDEPENDS = "libevas-engine-buffer libevas-engine-fb libevas-engine-software-generic libevas-engine-software-x11 libevas-loader-png"
+LICENSE = "MIT BSD"
+PV = "0.6.0+svnr${SRCREV}"
+PR = "r1"
+
+inherit autotools
+
+EXTRA_OECONF = "\
+  --x-includes=${STAGING_INCDIR}/X11 \
+  --x-libraries=${STAGING_LIBDIR} \
+  --enable-simple-x11 \
+\
+  --disable-opengl-glew \
+  --disable-opengl-x11 \
+  --enable-software-x11 \
+  --enable-xrender-x11 \
+  --enable-software-16-x11 \
+  --enable-fb \
+  --disable-software-ddraw \
+  --disable-software-16-ddraw \
+  --disable-direct3d \
+  --disable-software-sdl \
+"
+
+do_configure_append() {
+        find ${S} -name Makefile | xargs sed -i s:'-I$(includedir)':'-I.':g
+}
+
+FILES_${PN} += "${datadir}"
diff --git a/packages/e17/exquisite_svn.bb b/packages/e17/exquisite_svn.bb
new file mode 100644
index 0000000000..4c0a5678c8
--- /dev/null
+++ b/packages/e17/exquisite_svn.bb
@@ -0,0 +1,11 @@
+DESCRIPTION = "A psplash replacement for display"
+LICENSE = "MIT BSD"
+DEPENDS = "eet evas ecore embryo edje"
+PV = "0.0.1+svnr${SRCREV}"
+PR = "r1"
+
+SRCNAME = "exquisite"
+
+inherit e
+
+EXTRA_OECONF = "--with-edje-cc=${STAGING_BINDIR_NATIVE}/edje_cc"
diff --git a/packages/e17/illume_svn.bb b/packages/e17/illume_svn.bb
new file mode 100644
index 0000000000..c2ff6b889c
--- /dev/null
+++ b/packages/e17/illume_svn.bb
@@ -0,0 +1,54 @@
+DESCRIPTION = "Illume - A mobile UI module for the Enlightenment Window Manager"
+AUTHOR = "Rasterman"
+LICENSE = "MIT/BSD"
+DEPENDS = "e-wm eet evas ecore edje embryo efreet edbus edje-native embryo-native eet-native"
+PV = "0.0+svnr${SRCREV}"
+PR = "r13"
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk;module=illume;proto=http"
+S = "${WORKDIR}/${PN}"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "\
+  --x-includes=${STAGING_INCDIR}/X11 \
+  --x-libraries=${STAGING_LIBDIR} \
+  --enable-simple-x11 \
+  --with-edje-cc=${STAGING_BINDIR_NATIVE}/edje_cc \
+  --with-eet-eet=${STAGING_BINDIR_NATIVE}/eet \
+"
+
+RRECOMMENDS_${PN} = "\
+  wamerican \
+  ${PN}-config \
+  ${PN}-theme \
+  ${PN}-dicts-english-us \
+  ${PN}-keyboards-default \
+  ${PN}-keyboards-numbers \
+  ${PN}-keyboards-terminal \
+"
+
+PACKAGES =+ "\
+  ${PN}-config \
+  ${PN}-dicts-english-us \
+  ${PN}-keyboards-default \
+  ${PN}-keyboards-numbers \
+  ${PN}-keyboards-terminal \
+"
+PACKAGE_ARCH_${PN}-config = "all"
+PACKAGE_ARCH_${PN}-dicts-english-us = "all"
+PACKAGE_ARCH_${PN}-keyboards-default = "all"
+PACKAGE_ARCH_${PN}-keyboards-numbers = "all"
+
+FILES_${PN}-config = "${datadir}/enlightenment/data/config/*/* ${datadir}/illume"
+FILES_${PN}-dicts-english-us = "${libdir}/enlightenment/modules/illume/dicts/English_*.dic"
+FILES_${PN}-keyboards-default = "${libdir}/enlightenment/modules/illume/keyboards/Default.kbd"
+FILES_${PN}-keyboards-numbers = "${libdir}/enlightenment/modules/illume/keyboards/Numbers.kbd"
+FILES_${PN}-keyboards-terminal = "${libdir}/enlightenment/modules/illume/keyboards/Terminal.kbd"
+
+FILES_${PN} = "\
+  ${libdir}/enlightenment/modules/*/*.edj \
+  ${libdir}/enlightenment/modules/*/*.desktop \
+  ${libdir}/enlightenment/modules/*/*/* \
+"
+FILES_${PN}-dbg += "${libdir}/enlightenment/modules/*/*/.debug/"
diff --git a/packages/e17/rage_svn.bb b/packages/e17/rage_svn.bb
new file mode 100644
index 0000000000..d351ffd2a4
--- /dev/null
+++ b/packages/e17/rage_svn.bb
@@ -0,0 +1,12 @@
+DESCRIPTION = "Rage is a media center application based on EFL"
+AUTHOR = "Carsten 'The Rasterman' Heitzler"
+HOMEPAGE = "http://www.rasterman.com"
+LICENSE = "MIT BSD"
+DEPENDS = "evas ecore edje"
+SECTION = "x11/multimedia"
+PV = "0.3.0.042+svnr${SRCREV}"
+
+inherit autotools
+
+SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk;module=rage;proto=http"
+S = "${WORKDIR}/rage"