aboutsummaryrefslogtreecommitdiffstats
path: root/classes/module.bbclass
blob: 83463ac84c72e23905c325e065851f119df53cbd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
RDEPENDS += "kernel (${KERNEL_VERSION}) update-modules"
DEPENDS += "virtual/kernel"

inherit module-base

MODULE_MAKE_FLAGS = '\
	KERNEL_PATH=${STAGING_KERNEL_DIR}\
	KERNEL_SRC=${STAGING_KERNEL_DIR}\
	KDIR=${STAGING_KERNEL_DIR}\
	KERNELDIR=${STAGING_KERNEL_DIR}\
	KERNEL_VERSION=${KERNEL_VERSION}\
	CC="${KERNEL_CC}" LD="${KERNEL_LD}"\
	AR="${KERNEL_AR}"\
	'

module_do_compile() {
	unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
	oe_runmake ${MODULE_MAKE_FLAGS} ${MAKE_TARGETS}
}

module_do_install() {
	unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
	oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" ${MODULE_MAKE_FLAGS} modules_install
}

pkg_postinst_append () {
if [ -n "$D" ]; then
	exit 1
else
	depmod -a ${KERNEL_VERSION}
	update-modules || true
fi
}

pkg_postrm_append () {
	update-modules || true
}

EXPORT_FUNCTIONS do_compile do_install

FILES_${PN} = "/etc /lib/modules"