aboutsummaryrefslogtreecommitdiffstats
path: root/packages/linux/linux-openmoko_2.6.22.5.bb
blob: fc702c8719887797042f6cde9637e511d916b2ad (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
require linux.inc
require linux-openmoko.inc

DESCRIPTION = "Linux 2.6.x kernel for FIC SmartPhones shipping w/ OpenMoko"
VANILLA_VERSION = "2.6.22"
KERNEL_RELEASE = "2.6.22.5"

# If you use a rc, you will need to use this:
#PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}-moko11+svnr${SRCREV}"

PV = "${KERNEL_RELEASE}-moko11+svnr${SRCREV}"
PR = "r13"

KERNEL_IMAGETYPE = "uImage"
UBOOT_ENTRYPOINT = "30008000"

##############################################################
# source and patches
#
SRCREV_FORMAT = "patches"

SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
           ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;patch=1 \
	       svn://svn.openmoko.org/trunk/src/target/kernel;module=patches;proto=http \
           file://fix-EVIOCGRAB-semantics-2.6.22.5.patch;patch=1 \
           file://fix-gta01-flowcontrol2-2.6.22.5.patch;patch=1 \
           file://gta02-sound.patch;patch=1 \
           file://soc-core-suspend.patch;patch=1 \
           file://iis-suspend.patch;patch=1 \
           file://s3c24xx-pcm-suspend.patch;patch=1 \
           file://gta-vibro-pwm-suspend.patch;patch=1 \
           file://defconfig-${KERNEL_RELEASE}"

S = "${WORKDIR}/linux-${VANILLA_VERSION}"

##############################################################
# kernel image resides on a seperate flash partition (for now)
#
ALLOW_EMPTY = "1"

COMPATIBLE_HOST = "arm.*-linux"
COMPATIBLE_MACHINE = 'fic-gta01|fic-gta02'

CMDLINE = "unused -- bootloader passes ATAG list"

###############################################################
# module configs specific to this kernel
#

# usb
module_autoload_ohci-hcd = "ohci-hcd"
module_autoload_hci_usb = "hci_usb"
module_autoload_g_ether = "g_ether"
# audio
module_autoload_snd-soc-neo1973-wm8753 = "snd-soc-neo1973-wm8753"
module_autoload_snd-soc-neo1973-gta02-wm8753 = "snd-soc-neo1973-gta02-wm8753"
module_autoload_snd-pcm-oss = "snd-pcm-oss"
module_autoload_snd-mixer-oss = "snd-mixer-oss"

# sd/mmc
module_autoload_s3cmci = "s3cmci"

python do_patch_prepend() {
	def runcmd(cmd):
		import commands
		(status, output) = commands.getstatusoutput(cmd)
		if status != 0:
			raise Exception, "Status %i: %s" % (status >> 8, output)
		return output
	runcmd('mv %(WORKDIR)s/patches %(S)s/patches && cd %(S)s && '
	       'quilt push -av && mv patches patches.openmoko && '
	       'mv .pc .pc.old && mv %(WORKDIR)s/defconfig-%(KERNEL_RELEASE)s %(WORKDIR)s/defconfig' %
	       {'WORKDIR': bb.data.getVar('WORKDIR', d, 1),
		'S': bb.data.getVar('S', d, 1),
		'KERNEL_RELEASE': bb.data.getVar('KERNEL_RELEASE', d, 1)})
	del runcmd
}