aboutsummaryrefslogtreecommitdiffstats
path: root/packages/mplayer/mplayer_1.0pre6.bb
blob: c1ea58ef459e9060ba3196935b9a375566033edf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
DESCRIPTION = "Open Source multimedia player."
SECTION = "opie/multimedia"
PRIORITY = "optional"
HOMEPAGE = "http://www.mplayerhq.hu/"
DEPENDS = "virtual/libsdl libmad tremor-20021126 libogg libvorbis zlib libpng jpeg"
LICENSE = "GPL"
SRC_URI = "http://www1.mplayerhq.hu/MPlayer/releases/MPlayer-${PV}.tar.bz2 \
           file://Makefile.patch;patch=1 \
           file://sdl.patch;patch=0 \
           file://zlib.patch;patch=0 "
PR = "r1"

DEFAULT_PREFERENCE = "-1"

DEPENDS_c7x0 += "sharp-aticore"
PACKAGE_ARCH_c7x0 = "${MACHINE_ARCH}"
SRC_URI_append_c7x0 = "file://mplayer-w100_1.0pre3.1.modified.diff;patch=1 \
                       file://Makefile-vidix.patch;patch=0 "

S = "${WORKDIR}/MPlayer-${PV}"

PACKAGES =+ "postproc postproc-dev"

FILES_${PN} = "${bindir}/mplayer ${libdir}/mplayer/vidix/w100_vid.so"

FILES_postproc = " ${libdir}/libpostproc.so.0.0.0 ${libdir}/libpostproc.so.0"
FILES_postproc-dev = " ${includedir}/postproc/postprocess.h ${libdir}/libpostproc.so ${libdir}/libpostproc.a"

inherit autotools 

EXTRA_OECONF = " \
        --prefix=/usr \
		--mandir=${mandir} \
        --target=${TARGET_ARCH} \
        --enable-shared-pp \
        \
        --disable-win32 \
        --disable-macosx \
        --disable-dvdread \
        --disable-mpdvdkit \
        --disable-tv \
        --disable-tv-v4l \
        --disable-tv-v4l2 \
        --disable-tv-bsdbt848 \
        --disable-mencoder \
	--disable-live \
        \
        --enable-dynamic-plugins \
        --enable-fbdev \
        --enable-sdl \
        --with-sdl-config=${STAGING_BINDIR}/sdl-config \
        \
        --enable-mad \
        --enable-tremor \
        --enable-vorbis \
        \
        --enable-ossaudio \
        \
        --with-extralibdir=${STAGING_LIBDIR} "

EXTRA_OECONF_append_corgi = " --enable-vidix "
EXTRA_OECONF_append_shepherd = " --enable-vidix "
EXTRA_OECONF_append_husky = " --enable-vidix "

do_configure() {
        ./configure ${EXTRA_OECONF}
}

do_install_append () {
        install -d ${D}${libdir} ${D}${includedir} ${D}${includedir}/postproc
        install -m 0644 libavcodec/libpostproc/postprocess.h ${D}${includedir}/postproc/
        oe_libinstall -so -C ${S}/libavcodec/libpostproc libpostproc ${D}${libdir}
        cp ${S}/libavcodec/libpostproc/libpostproc.so ${D}${libdir}/libpostproc.so.0.0.0
        cd ${D}${libdir}
        ln -sf libpostproc.so.0.0.0 libpostproc.so.0
        ln -sf libpostproc.so.0 libpostproc.so
}

do_stage () {
        oe_libinstall -a -so -C libavcodec/libpostproc libpostproc ${STAGING_LIBDIR}
        cd ${STAGING_LIBDIR}
        ln -sf libpostproc.so libpostproc.so.0.0.0
        ln -sf libpostproc.so libpostproc.so.0

        install -d ${STAGING_INCDIR}/postproc
        install -m 0644 ${S}/libavcodec/libpostproc/postprocess.h ${STAGING_INCDIR}/postproc/postprocess.h
}