aboutsummaryrefslogtreecommitdiff
path: root/recipes/eglibc/eglibc-initial.inc
blob: 4aaf8fb56451b35faaf7edf158579fcdf0454948 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
SECTION = "libs"
DEPENDS = "linux-libc-headers virtual/${TARGET_PREFIX}gcc-initial"
PROVIDES = "virtual/${TARGET_PREFIX}libc-initial"

PACKAGES = ""
PACKAGES_DYNAMIC = ""

do_configure () {
	sed -ie 's,{ (exit 1); exit 1; }; },{ (exit 0); }; },g' ${S}/configure
	chmod +x ${S}/configure
        (cd ${S} && gnu_configize) || die "failure in running gnu-configize"
        find ${S} -name "configure" | xargs touch
	${S}/configure --host=${TARGET_SYS} --build=${BUILD_SYS} \
		--prefix=/usr \
		--without-cvs --disable-sanity-checks \
		--with-headers=${STAGING_DIR_TARGET}${includedir} \
		--enable-hacker-mode --enable-addons
}

do_compile () {
	:
}

do_install () {
       oe_runmake cross-compiling=yes install_root=${D} \
       includedir='${includedir}' prefix='${prefix}' \
       libdir='${libdir}' slibdir='${base_libdir}' \
       localedir='${libdir}/locale' \
       install-bootstrap-headers=yes install-headers

       oe_runmake includedir='${includedir}' prefix='${prefix}' \
       libdir='${libdir}' slibdir='${base_libdir}' \
       localedir='${libdir}/locale' \
       csu/subdir_lib
       # Two headers -- stubs.h and features.h -- aren't installed by install-headers,
       # so do them by hand.  We can tolerate an empty stubs.h for the moment.
       # See e.g. http://gcc.gnu.org/ml/gcc/2002-01/msg00900.html
       mkdir -p ${D}${includedir}/gnu/
       touch ${D}${includedir}/gnu/stubs.h
       cp ${S}/include/features.h ${D}${includedir}/features.h

       if [ -e ${B}/bits/stdio_lim.h ]; then
               cp ${B}/bits/stdio_lim.h  ${D}${includedir}/bits/
       fi
       mkdir -p ${D}${libdir}/
       install -m 644 csu/crt[1in].o ${D}${libdir}
       ${CC} -nostdlib -nostartfiles -shared -x c /dev/null \
               -o ${D}${libdir}/libc.so
}