aboutsummaryrefslogtreecommitdiffstats
path: root/recipes/gnome/gnome-vfs_2.24.1.bb
blob: e47f28db0c8f0e2d8b2e3fa072ecb4c543aa20cb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
LICENSE = "GPL"
DEPENDS = "libxml2 gconf gnutls avahi dbus dbus-glib bzip2 gnome-mime-data zlib gtk-doc-native"
RRECOMMENDS_${PN} = "gnome-vfs-plugin-file shared-mime-info"
# Some legacy packages will require gnome-mime-data to be installed, but use of
# it is deprecated.
PR = "r3"

inherit gnome

SRC_URI += "file://gconftool-lossage.patch \
	    file://gnome-vfs-no-kerberos.patch;striplevel=0 \
	    file://03_gnutls27.patch"

# This is to provide compatibility with the gnome-vfs DBus fork
PROVIDES = "gnome-vfs-plugin-dbus"
RREPLACES_${PN} = "gnome-vfs-dbus"

EXTRA_OECONF = " \
                 --disable-openssl \
                 --enable-gnutls \
                 --enable-avahi \
                 --with-samba-includes=${STAGING_INCDIR} \
               "

do_configure_prepend() {
        sed -i -e 's:	doc	::g' Makefile.am
}

PACKAGES_DYNAMIC = "gnome-vfs-plugin-*"

python populate_packages_prepend () {
	print bb.data.getVar('FILES_gnome-vfs', d, 1)

	plugindir = bb.data.expand('${libdir}/gnome-vfs-2.0/modules/', d)
	do_split_packages(d, plugindir, '^lib(.*)\.so$', 'gnome-vfs-plugin-%s', 'GNOME VFS plugin for %s')
}

FILES_${PN} += "${libdir}/vfs ${datadir}/dbus-1/services"
FILES_${PN}-dbg += "${libdir}/gnome-vfs-2.0/modules/.debug"
FILES_${PN}-dev += "${libdir}/gnome-vfs-2.0/include \
                    ${libdir}/gnome-vfs-2.0/modules/*.a \
                    ${libdir}/gnome-vfs-2.0/modules/*.la \
                   "
FILES_${PN}-doc += "${datadir}/gtk-doc"



SRC_URI[archive.md5sum] = "100f9af16dc659e375ee8da45175a28d"
SRC_URI[archive.sha256sum] = "bc59144e303b152b84b86f209347a3e87a91d5ed7172d8503ee19c232dcabeb6"