blob: e9aae0ad2515b82e81b381059a4998613cb48275 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
require linux.inc
require linux-ixp4xx.inc
VANILLA_VERSION = "2.6.23"
KERNEL_RELEASE = "2.6.23.14"
# If you use a rc, you will need to use this:
#PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCPV}"
PV = "${KERNEL_RELEASE}+svnr${SRCPV}"
PR = "r0"
SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2;name=kernel \
${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;patch=1;name=patch \
svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
file://defconfig-${KERNEL_RELEASE}"
S = "${WORKDIR}/linux-${VANILLA_VERSION}"
# Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
do_postpatch() {
# Move away OE patches which have been already applied.
mv ${S}/patches ${S}/patches.oe
mv .pc .pc.oe
# Move the NSLU2 patches in place for quilt and apply them.
mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
# Store the NSLU2 patches
mv ${S}/patches ${S}/patches.ixp4xx
mv .pc .pc.ixp4xx
# And move back the OE patches
mv ${S}/patches.oe ${S}/patches
mv .pc.oe .pc
# Copy the defconfig into ${WORKDIR}
mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
}
addtask postpatch after do_patch before do_configure
SRC_URI[patch.md5sum] = "11d3513c45bdcbdf9c75364e747568bd"
SRC_URI[patch.sha256sum] = "98bc6743595f824892fe72339251139172795dba18927565e4d61b06251e66f5"
SRC_URI[kernel.md5sum] = "2cc2fd4d521dc5d7cfce0d8a9d1b3472"
SRC_URI[kernel.sha256sum] = "d4e67c0935ffb2a4158234bff92cc791b83177866009fc9b2214104e0038dbdb"
|
