qmake2: import from OE

We want to have a seperate qmake for the time being, but eventually all tweaks should move into qt4-tools

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>

4 files changed, 131 insertions, 0 deletions

diff --git a/recipes-qt/qt4/qmake2-sdk/linux-oe-qmake.conf b/recipes-qt/qt4/qmake2-sdk/linux-oe-qmake.conf
new file mode 100644
index 0000000000..f58481a693
--- /dev/null
+++ b/recipes-qt/qt4/qmake2-sdk/linux-oe-qmake.conf
@@ -0,0 +1 @@
+include(../linux-g++/qmake.conf)
diff --git a/recipes-qt/qt4/qmake2.inc b/recipes-qt/qt4/qmake2.inc
new file mode 100644
index 0000000000..f2631b5f7e
--- /dev/null
+++ b/recipes-qt/qt4/qmake2.inc
@@ -0,0 +1,69 @@
+DESCRIPTION = "TrollTech Makefile Generator"
+PRIORITY = "optional"
+HOMEPAGE = "http://www.trolltech.com"
+SECTION = "devel"
+LICENSE = "GPL"
+PR = "r12"
+
+# We call 'moc' during the build 
+DEPENDS = "qt4-tools-native"
+
+QTVER = "qt-embedded-linux-opensource-src-${QTVERSION}"
+
+SRC_URI = "ftp://ftp.trolltech.com/qt/source/${QTVER}.tar.bz2 \
+           file://0001-fix-mkspecs.patch \
+           file://qt-config.patch \
+           file://use-lflags-last.patch \
+           file://linux-oe-qmake.conf"
+S = "${WORKDIR}/${QTVER}"
+
+inherit autotools  
+
+CROSSHACK = "true"
+CROSSHACK_virtclass-native = ""
+CROSSHACK_virtclass-nativesdk = ""
+
+export CROSSHACK
+export QTDIR = "${S}"
+EXTRA_OEMAKE = "-e"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_configure() {
+
+    # Make sure we regenerate all Makefiles 
+    find ${S} -name "Makefile" | xargs rm
+    # Install the OE build templates
+    for template in linux-oe-g++ linux-uclibc-oe-g++ linux-gnueabi-oe-g++ linux-uclibceabi-oe-g++
+    do
+        install -d ${S}/mkspecs/$template
+        install -m 0644 ${WORKDIR}/linux-oe-qmake.conf ${S}/mkspecs/$template/qmake.conf
+        ln -sf ../linux-g++/qplatformdefs.h ${S}/mkspecs/$template/qplatformdefs.h
+    done
+
+    QMAKESPEC=
+    PLATFORM=${HOST_OS}-oe-g++
+    export PLATFORM
+    export OE_QMAKE_CC="${CC}"
+    export OE_QMAKE_CFLAGS="${CFLAGS}"
+    export OE_QMAKE_CXX="${CXX}"
+    export OE_QMAKE_CXXFLAGS="-fno-exceptions -fno-rtti ${CXXFLAGS}"
+    export OE_QMAKE_LDFLAGS="${LDFLAGS}"
+    export OE_QMAKE_LINK="${CCLD}"
+    export OE_QMAKE_AR="${AR}"
+    export OE_QMAKE_STRIP="${STRIP}"
+    export OE_QMAKE_UIC="${STAGING_BINDIR_NATIVE}/uic4"
+    export OE_QMAKE_MOC="${STAGING_BINDIR_NATIVE}/moc4"
+    export QMAKE_MOC="${STAGING_BINDIR_NATIVE}/moc4"
+    export OE_QMAKE_RCC="${STAGING_BINDIR_NATIVE}/rcc4"
+    export QMAKE_RCC="${STAGING_BINDIR_NATIVE}/rcc4"
+    export OE_QMAKE_QMAKE="${STAGING_BINDIR_NATIVE}/qmake"
+    export OE_QMAKE_RPATH="-Wl,-rpath-link,"
+    echo yes | ./configure -prefix ${STAGING_DIR_NATIVE}/qt4 ${EXTRA_OECONF} || die "Configuring qt failed"
+}
+
+do_compile() {
+    :
+}
+
+FILES_${PN} += "${datadir}/qt4/"
diff --git a/recipes-qt/qt4/qmake2/linux-oe-qmake.conf b/recipes-qt/qt4/qmake2/linux-oe-qmake.conf
new file mode 100644
index 0000000000..f58481a693
--- /dev/null
+++ b/recipes-qt/qt4/qmake2/linux-oe-qmake.conf
@@ -0,0 +1 @@
+include(../linux-g++/qmake.conf)
diff --git a/recipes-qt/qt4/qmake2_2.10a.bb b/recipes-qt/qt4/qmake2_2.10a.bb
new file mode 100644
index 0000000000..77d909f8eb
--- /dev/null
+++ b/recipes-qt/qt4/qmake2_2.10a.bb
@@ -0,0 +1,60 @@
+QTVERSION="4.4.3"
+FILESDIR += "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/qmake2"
+
+BBCLASSEXTEND = "native sdk"
+
+require ${PN}.inc
+
+SRC_URI += "file://qmake-hack.diff"
+
+do_install() {
+    install -d ${D}/${bindir}
+    install -m 0755 bin/qmake ${D}/${bindir}/qmake2
+    install -m 0755 bin/qmake ${D}/${bindir}/qmake-qt4
+    install -d ${D}/${datadir}/qt4
+    install -d ${D}/${datadir}/qtopia
+
+    script="${D}/${datadir}/qtopia/environment-setup"
+    touch $script
+    echo 'export QT_DIR_NAME=qtopia' >> $script
+    echo 'export QT_LIBINFIX=E' >> $script
+    echo 'export OE_QMAKE_AR=ar' >> $script
+    echo 'export OE_QMAKE_CC=gcc' >> $script
+    echo 'export OE_QMAKE_CXX=g++' >> $script
+    echo 'export OE_QMAKE_LINK=g++' >> $script
+    echo 'export OE_QMAKE_LIBDIR_QT=${libdir}' >> $script
+    echo 'export OE_QMAKE_INCDIR_QT=${includedir}/qtopia' >> $script
+    echo 'export OE_QMAKE_MOC=${bindir}/moc' >> $script
+    echo 'export OE_QMAKE_UIC=${bindir}/uic' >> $script
+    echo 'export OE_QMAKE_UIC3=${bindir}/uic3' >> $script
+    echo 'export OE_QMAKE_RCC=${bindir}/rcc' >> $script
+    echo 'export OE_QMAKE_QDBUSCPP2XML=${bindir}/qdbuscpp2xml' >> $script
+    echo 'export OE_QMAKE_QDBUSXML2CPP=${bindir}/qdbusxml2cpp' >> $script
+    echo 'export OE_QMAKE_QT_CONFIG=${datadir}/qtopia/mkspecs/qconfig.pri' >> $script
+    echo 'export QMAKESPEC=${datadir}/qtopia/mkspecs/linux-g++' >> $script
+
+    script="${D}/${datadir}/qt4/environment-setup"
+    touch $script
+    echo 'export OE_QMAKE_AR=ar' >> $script
+    echo 'export OE_QMAKE_CC=gcc' >> $script
+    echo 'export OE_QMAKE_CXX=g++' >> $script
+    echo 'export OE_QMAKE_LINK=g++' >> $script
+    echo 'export OE_QMAKE_LIBDIR_QT=${libdir}' >> $script
+    echo 'export OE_QMAKE_INCDIR_QT=${includedir}/qt4' >> $script
+    echo 'export OE_QMAKE_MOC=${bindir}/moc' >> $script
+    echo 'export OE_QMAKE_UIC=${bindir}/uic' >> $script
+    echo 'export OE_QMAKE_UIC3=${bindir}/uic3' >> $script
+    echo 'export OE_QMAKE_RCC=${bindir}/rcc' >> $script
+    echo 'export OE_QMAKE_QDBUSCPP2XML=${bindir}/qdbuscpp2xml' >> $script
+    echo 'export OE_QMAKE_QDBUSXML2CPP=${bindir}/qdbusxml2cpp' >> $script
+    echo 'export OE_QMAKE_QT_CONFIG=${datadir}/qt4/mkspecs/qconfig.pri' >> $script
+    echo 'export QMAKESPEC=${datadir}/qt4/mkspecs/linux-g++' >> $script
+
+    chmod 0755 ${D}${datadir}/qt*/environment-setup
+}
+
+FILES_${PN} += "${datadir}/qt*/environment-setup"
+
+
+SRC_URI[md5sum] = "9a639aec44a1e4c70040117183d247a3"
+SRC_URI[sha256sum] = "05d06b93f95092f1318634fca24f0c2d0a1252c9f1dc2fbb427b07e8ecbb4f39"