From 9569d222eb8ded7a8a5d9ed279b92605c46cd111 Mon Sep 17 00:00:00 2001
From: Andreas Müller <schnitzeltony@gmail.com>
Date: Tue, 6 Jul 2021 11:13:19 +0200
Subject: blueman: upgrade 2.1.4 -> 2.2.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Manually refresh 0002-fix-fail-to-enable-bluetooth.patch - it did not apply

2.2.1
Bugs fixed
    Hard dependency of DBusService on NetworkManager

2.2
New features
    Disconnect items in applet menu (plugin)
    Desktop notifications on connect / disconnect (plugin)
    Notifications with battery level for connecting devices (applet plugin)
    Stop discovery and retry connection for broken adapter drivers
    Auto-connect settings for supported services

Changes
    Drop blueman-report
    Drop blueman-assistant
    Raise minimum Python version to 3.6
    Raise GTK+ 3 version to 3.22
    Raise minimum BlueZ version to 5.48
    Allow opening device menus via keyboard (Shift+F10 or menu key)
    Add Ctrl+Q and Ctrl+W accelerators for closing blueman-manager
    Allow cancelling device connection attempts
    Improved passkey handling (fixed padding, highlighting, single notifitication)
    Hide devices with no name

Bugs fixed
    Fix disconnecting NMDevice
    Exceptions from asynchronous DBus calls (getting picked up by tools like Apport or ABRT)
    DiscvManager plugin showed its icon unreliably

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../recipes-connectivity/blueman/blueman_2.2.1.bb  | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 meta-networking/recipes-connectivity/blueman/blueman_2.2.1.bb

(limited to 'meta-networking/recipes-connectivity/blueman/blueman_2.2.1.bb')

diff --git a/meta-networking/recipes-connectivity/blueman/blueman_2.2.1.bb b/meta-networking/recipes-connectivity/blueman/blueman_2.2.1.bb
new file mode 100644
index 0000000000..3cb01ff71e
--- /dev/null
+++ b/meta-networking/recipes-connectivity/blueman/blueman_2.2.1.bb
@@ -0,0 +1,57 @@
+DESCRIPTION = "Blueman is a GTK+ Bluetooth Manager"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+DEPENDS = "bluez5 python3-pygobject python3-cython-native python3-setuptools-native intltool-native"
+
+inherit autotools gettext systemd gsettings python3native gtk-icon-cache
+
+SRC_URI = " \
+    https://github.com/blueman-project/blueman/releases/download/${PV}/blueman-${PV}.tar.xz \
+    file://0001-Search-for-cython3.patch \
+    file://0002-fix-fail-to-enable-bluetooth.patch \
+"
+SRC_URI[sha256sum] = "fcc10a2259bef2c5ac63f577010d76caed460d68810b7f70fecf056bf10a1a72"
+
+EXTRA_OECONF = " \
+    --disable-appindicator \
+    --disable-runtime-deps-check \
+    --disable-schemas-compile \
+"
+
+SYSTEMD_SERVICE_${PN} = "${BPN}-mechanism.service"
+SYSTEMD_AUTO_ENABLE_${PN} = "disable"
+
+RRECOMENDS_${PN} += "adwaita-icon-theme"
+RDEPENDS_${PN} += " \
+    python3-core \
+    python3-dbus \
+    packagegroup-tools-bluetooth \
+"
+
+PACKAGECONFIG ??= "thunar"
+PACKAGECONFIG[thunar] = "--enable-thunar-sendto,--disable-thunar-sendto"
+
+FILES_${PN} += " \
+    ${datadir}/dbus-1 \
+    ${datadir}/Thunar \
+    ${systemd_user_unitdir} \
+    ${exec_prefix}${systemd_system_unitdir} \
+    ${PYTHON_SITEPACKAGES_DIR} \
+"
+
+FILES_${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/_blueman.a"
+
+# In code, path to python is a variable that is replaced with path to native version of it
+# during the configure stage, e.g ../recipe-sysroot-native/usr/bin/python3-native/python3.
+# Replace it with #!/usr/bin/env python3
+do_install_append() {
+    sed -i "1s/.*/#!\/usr\/bin\/env python3/" ${D}${prefix}/libexec/blueman-rfcomm-watcher \
+                                              ${D}${prefix}/libexec/blueman-mechanism \
+                                              ${D}${bindir}/blueman-adapters \
+                                              ${D}${bindir}/blueman-applet \
+                                              ${D}${bindir}/blueman-manager \
+                                              ${D}${bindir}/blueman-sendto \
+                                              ${D}${bindir}/blueman-services \
+                                              ${D}${bindir}/blueman-tray
+}
-- 
cgit 1.2.3-korg