# It really depends on order of the layers appearing in BBLAYERS
# variable in toplevel bblayers.conf file, where bitbake will search
# for .inc files and others where bitbake uses BBPATH since it will
# search the directories from first to last as specified in BBPATH
# Therefore if you want a given layer to be considered high priority
# for the .inc and .conf etc. then consider it adding at the beginning
# of BBPATH. For bblayers bitbake will use BBFILES_PRIORITY to resolve
# the recipe contention so the order of directories in BBFILES does 
# not matter.

# We have a conf and classes directory, append to BBPATH
BBPATH .= ":${LAYERDIR}"

# We have a recipes directory, add to BBFILES
BBFILES += "\
  ${LAYERDIR}/recipes-*/*/*.bb \
  ${LAYERDIR}/oe-core/recipes-*/*/*.bbappend \
  ${LAYERDIR}/meta-oe/recipes-*/*/*.bbappend \
  ${@base_contains('BBFILE_COLLECTIONS', 'systemd-layer',\
                   '', '${LAYERDIR}/invalid.bb', d)} \
  ${@base_contains('BBFILE_COLLECTIONS', 'gnome-layer',\
                   '${LAYERDIR}/meta-gnome/recipes-*/*/*.bbappend', '', d)} \
  ${@base_contains('BBFILE_COLLECTIONS', 'efl-layer',\
                   '${LAYERDIR}/meta-efl/recipes-*/*/*.bbappend', '', d)} \
  ${@base_contains('BBFILE_COLLECTIONS', 'multimedia-layer',\
                   '${LAYERDIR}/meta-multimedia/recipes-*/*/*.bbappend', '', d)} \
  ${@base_contains('BBFILE_COLLECTIONS', 'networking',\
                   '${LAYERDIR}/meta-networking/recipes-*/*/*.bbappend', '', d)} \
  ${@base_contains('BBFILE_COLLECTIONS', 'xfce-layer',\
                   '${LAYERDIR}/meta-xfce/recipes-*/*/*.bbappend', '', d)} \
"

BBFILE_COLLECTIONS += "systemd-layer"
BBFILE_PATTERN_systemd-layer := "^${LAYERDIR}/"

# Define the priority for recipes (.bb files) from this layer,
# choosing carefully how this layer interacts with all of the
# other layers.

BBFILE_PRIORITY_systemd-layer = "7"

SIGGEN_EXCLUDERECIPES_ABISAFE += " \
  systemd-serialgetty \
"