blob: 1f3f6112bdb38e3017f5bf2d759f22e4479d5d9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
SUMMARY = "GTK+ applet for NetworkManager"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
DEPENDS = "gtk+3 libnotify libsecret networkmanager \
gconf libgnome-keyring iso-codes nss \
intltool-native \
"
GNOMEBASEBUILDCLASS = "autotools-brokensep"
inherit distro_features_check gnomebase gsettings gtk-icon-cache gobject-introspection gettext
REQUIRED_DISTRO_FEATURES = "x11"
SRC_URI[archive.md5sum] = "e0373f4c0d0637716e6e385799a9080f"
SRC_URI[archive.sha256sum] = "ebef1c1050ff6d94cad060e8d259f2a88ae159cf83ca75cb71d9f76867877eed"
PACKAGECONFIG[modemmanager] = "--with-wwan,--without-wwan,modemmanager"
PACKAGECONFIG[mobile-provider-info] = "--enable-mobile-broadband-provider-info,--disable-mobile-broadband-provider-info,mobile-broadband-provider-info,mobile-broadband-provider-info"
PACKAGECONFIG ??= ""
EXTRA_OECONF = " \
--without-selinux \
"
do_configure_append() {
# Sigh... --enable-compile-warnings=no doesn't actually turn off -Werror
for i in $(find ${B} -name "Makefile") ; do
sed -i -e s%-Werror[^[:space:]]*%%g $i
done
}
# gobject-introspection related
GI_DATA_ENABLED_libc-musl = "False"
do_compile_prepend() {
export GIR_EXTRA_LIBS_PATH="${B}/src/libnma/.libs"
}
RDEPENDS_${PN} =+ "networkmanager"
FILES_${PN} += " \
${datadir}/nm-applet/ \
${datadir}/libnma/wifi.ui \
${datadir}/metainfo \
"
# musl builds generate gir files which otherwise go un-packaged
FILES_${PN}-dev += " \
${datadir}/gir-1.0 \
"
|
