blob: c355dadf0b0ce039ef24668860a890c819f0e9e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
SUMMARY = "GNU All Mobile Managment Utilities"
SECTION = "console/network"
DEPENDS = "cmake-native virtual/libiconv libdbi mysql5 glib-2.0 udev libgudev unixodbc"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=a17cb0a873d252440acfdf9b3d0e7fbf"
HOMEPAGE = "http://www.gammu.org/"
SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}/${PV}/${BP}.tar.bz2 \
file://gammurc \
file://gammu-smsdrc \
"
SRC_URI[md5sum] = "8ea16c6b3cc48097a8e62311fe0e25b9"
SRC_URI[sha256sum] = "de67caa102aa4c8fbed5300e5a0262e40411c4cc79f4379a8d34eed797968fc3"
inherit distutils3 cmake gettext
do_install:append() {
# these files seem to only be used by symbian and trigger QA warnings
rm -rf ${D}/usr/share/gammu
#install default configuration files
install -d ${D}${sysconfdir}
install -m 0644 ${WORKDIR}/gammurc ${D}${sysconfdir}/gammurc
install -m 0644 ${WORKDIR}/gammu-smsdrc ${D}${sysconfdir}/gammu-smsdrc
}
EXTRA_OECONF = " \
--enable-shared \
--enable-backup \
--enable-protection \
"
EXTRA_OECMAKE = " \
-DWITH_CURL=OFF \
-DWITH_BLUETOOTH=OFF \
-DWITH_NOKIA_SUPPORT=OFF \
-DWITH_IRDA=OFF \
-DWITH_PYTHON=OFF \
-DWITH_MySQL=ON \
-DWITH_Postgres=OFF \
"
PACKAGES =+ "${PN}-smsd libgammu libgsmsd python-${PN}"
FILES:${PN} = "${bindir}/gammu ${bindir}/jadmaker ${sysconfdir}/bash_completion.d/gammu \
${bindir}/gammu-detect ${sysconfdir}/gammurc"
CONFFILES:${PN} = "${sysconfdir}/gammurc"
FILES:${PN}-smsd = "${bindir}/gammu-smsd* ${sysconfdir}/gammu-smsdrc"
CONFFILES:${PN}-smsd = "${sysconfdir}/gammu-smsdrc"
FILES:${PN}-dev += "${bindir}/gammu-config ${libdir}/*.so"
FILES:${PN}-dbg += "${bindir}/.debug ${libdir}/.debug ${PYTHON_SITEPACKAGES_DIR}/gammu/.debug"
FILES:libgammu = "${libdir}/libGammu.so.*"
FILES:libgsmsd = "${libdir}/libgsmsd.so.*"
FILES:python-${PN} = "${PYTHON_SITEPACKAGES_DIR}/gammu/*.??"
RDEPENDS:${PN} += "bash"
RDEPENDS:${PN}-dev += "bash"
# Fails to build with thumb-1 (qemuarm)
# gammu-1.32.0/libgammu/service/sms/gsmems.c:542:1: internal compiler error: in patch_jump_insn, at cfgrtl.c:1275
# | }
# | ^
# | Please submit a full bug report,
# | with preprocessed source if appropriate.
# | See <http://gcc.gnu.org/bugs.html> for instructions.
# | make[2]: *** [libgammu/CMakeFiles/libGammu.dir/service/sms/gsmems.o] Error 1
# | make[2]: *** Waiting for unfinished jobs....
ARM_INSTRUCTION_SET = "arm"
|
