blob: 4b072fc5dc7249e5752f1992303e4271c5e0d79b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
SUMMARY = "Crypto and TLS for C++11"
HOMEPAGE = "https://botan.randombit.net"
LICENSE = "BSD-2-Clause"
LIC_FILES_CHKSUM = "file://license.txt;md5=f4ce98476c07c34e1793daa036960fad"
SECTION = "libs"
SRC_URI = "https://botan.randombit.net/releases/Botan-${PV}.tar.xz"
SRC_URI[sha256sum] = "e26e00cfefda64082afdd540d3c537924f645d6a674afed2cd171005deff5560"
S = "${WORKDIR}/Botan-${PV}"
inherit python3native siteinfo lib_package
CPU ?= "${TARGET_ARCH}"
CPU:x86 = "x86_32"
CPU:armv7a = "armv7"
CPU:armv7ve = "armv7"
do_configure() {
python3 ${S}/configure.py \
--prefix="${D}${exec_prefix}" \
--libdir="${D}${libdir}" \
--cpu="${CPU}" \
--cc-bin="${CXX}" \
--cxxflags="${CXXFLAGS}" \
--ldflags="${LDFLAGS}" \
--with-endian=${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
${@bb.utils.contains("TUNE_FEATURES","neon","","--disable-neon",d)} \
--with-sysroot-dir=${STAGING_DIR_HOST} \
--with-build-dir="${B}" \
--optimize-for-size \
--with-stack-protector \
--enable-shared-library \
--with-python-versions=3 \
${EXTRA_OECONF}
}
do_compile() {
oe_runmake
}
do_install() {
oe_runmake install
sed -i -e "s|${D}||g" ${D}${libdir}/pkgconfig/botan-2.pc
}
PACKAGES += "${PN}-python3"
FILES:${PN}-python3 = "${libdir}/python3"
RDEPENDS:${PN}-python3 += "python3"
COMPATIBLE_HOST:riscv32 = "null"
|
