aboutsummaryrefslogtreecommitdiffstats
path: root/meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb
diff options
context:
space:
mode:
authorLi xin <lixin.fnst@cn.fujitsu.com>2015-08-05 13:35:26 +0800
committerMartin Jansa <Martin.Jansa@gmail.com>2015-08-24 13:54:01 +0200
commitfe9d64dbf6a897de6813fe7a69ef305512c3d30b (patch)
treee020eeeab35cd3f8f3d832981e350545f741246a /meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb
parentf67e041c407a04079f4ffbdd7669ddf152fc0685 (diff)
downloadmeta-openembedded-fe9d64dbf6a897de6813fe7a69ef305512c3d30b.tar.gz
meta-openembedded-fe9d64dbf6a897de6813fe7a69ef305512c3d30b.tar.bz2
meta-openembedded-fe9d64dbf6a897de6813fe7a69ef305512c3d30b.zip
luajit: upgrade 2.0.3 -> 2.0.4
License COPYRIGHT year changed. Signed-off-by: Li Xin <lixin.fnst@cn.fujitsu.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Diffstat (limited to 'meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb')
-rw-r--r--meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb56
1 files changed, 56 insertions, 0 deletions
diff --git a/meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb b/meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb
new file mode 100644
index 000000000..4a15a4e1b
--- /dev/null
+++ b/meta-oe/recipes-devtools/luajit/luajit_2.0.4.bb
@@ -0,0 +1,56 @@
+SUMMARY = "Just-In-Time Compiler for Lua"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=3992f1fbae3b8b061f9056b7fcda8cc6"
+HOMEPAGE = "http://luajit.org"
+
+SRC_URI = "http://luajit.org/download/LuaJIT-${PV}.tar.gz \
+ file://0001-Do-not-strip-automatically-this-leaves-the-stripping.patch \
+"
+SRC_URI[md5sum] = "dd9c38307f2223a504cbfb96e477eca0"
+SRC_URI[sha256sum] = "620fa4eb12375021bef6e4f237cbd2dd5d49e56beb414bee052c746beef1807d"
+
+S = "${WORKDIR}/LuaJIT-${PV}"
+
+inherit pkgconfig binconfig
+
+BBCLASSEXTEND = "native"
+
+do_configure_prepend() {
+ sed -i 's:PREFIX= /usr/local:PREFIX= ${prefix}:g' ${S}/Makefile
+ sed -i 's:MULTILIB= lib:MULTILIB= ${baselib}:g' ${S}/Makefile
+}
+
+EXTRA_OEMAKE = 'CROSS=${HOST_PREFIX} \
+ TARGET_CFLAGS="${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}" \
+ TARGET_LDFLAGS="${TOOLCHAIN_OPTIONS}" \
+ TARGET_SHLDFLAGS="${TOOLCHAIN_OPTIONS}"'
+EXTRA_OEMAKE_append_powerpc = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_x86 = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_x86-64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_powerpc64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_arm = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_mips64 = ' HOST_CC="${BUILD_CC} -m32"'
+
+do_compile () {
+ oe_runmake
+}
+
+do_install () {
+ oe_runmake 'DESTDIR=${D}' install
+ rmdir ${D}${datadir}/lua/5.* \
+ ${D}${datadir}/lua \
+ ${D}${libdir}/lua/5.* \
+ ${D}${libdir}/lua
+}
+
+PACKAGES += 'luajit-common'
+
+FILES_${PN} += "${libdir}/libluajit-5.1.so.2 \
+ ${libdir}/libluajit-5.1.so.${PV} \
+"
+FILES_${PN}-dev += "${libdir}/libluajit-5.1.a \
+ ${libdir}/libluajit-5.1.so \
+ ${libdir}/pkgconfig/luajit.pc \
+"
+FILES_luajit-common = "${datadir}/${BPN}-${PV}"
+