blob: 3e6a5ba71103e3166518d854982ad2501665695d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
SUMMARY = "File manager for GNOME"
SECTION = "x11/gnome"
LICENSE="GPLv3"
LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
GNOMEBASEBUILDCLASS = "meson"
DEPENDS = " \
fontconfig \
gtk+3 \
gnome-desktop3 \
gsettings-desktop-schemas \
gnome-autoar \
tracker \
libhandy \
libportal \
"
inherit gnomebase gsettings gobject-introspection gtk-doc gettext features_check mime-xdg
def gnome_verdir(v):
return oe.utils.trim_version(v, 1)
SRC_URI[archive.sha256sum] = "b71ef2fe07e5eea89a2bb1e5bd30947bd18873bfb30f79cbf17edfbd4d20f60d"
REQUIRED_DISTRO_FEATURES = "x11"
EXTRA_OEMESON += " \
-Dtests=none \
"
PACKAGECONFIG = "extensions"
PACKAGECONFIG[extensions] = "-Dextensions=true,-Dextensions=false, gexiv2 gstreamer1.0-plugins-base"
FILES:${PN} += " \
${datadir}/dbus-1 \
${datadir}/metainfo \
${datadir}/gnome-shell \
${datadir}/tracker3 \
"
# mandatory - not checked during configuration:
# | (org.gnome.Nautilus:863): GLib-GIO-ERROR **: 21:03:52.326: Settings schema 'org.freedesktop.Tracker.Miner.Files' is not installed
RDEPENDS:${PN} += "tracker-miners"
|
