aboutsummaryrefslogtreecommitdiffstats
path: root/meta-oe/recipes-extended/atftp/atftp_git.bb
blob: 67a2c1b4c5ac004a6716309eb0860ccdc395ca81 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
DESCRIPTION = "Advanced TFTP server and client"
SECTION = "network"
HOMEPAGE = "http://packages.debian.org/atftp"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://LICENSE;md5=94d55d512a9ba36caa9b7df079bae19f"
PV = "0.7.1+git${SRCPV}"
PR = "r3"

SRCREV = "be3291a18c069ae23a124ffdc56d64a5ff0bbec7"

SRC_URI = "git://atftp.git.sourceforge.net/gitroot/atftp/atftp;protocol=git \
           file://atftpd-0.7_circumvent_tftp_size_restrictions.patch \
           file://atftpd-0.7_unprotected_assignments_crash.patch \
           file://atftpd.init \
           file://atftpd.service \   
          "
S = "${WORKDIR}/git"

inherit autotools update-rc.d useradd systemd

INITSCRIPT_PACKAGES = "${PN}d"
INITSCRIPT_NAME_${PN}d = "atftpd"
INITSCRIPT_PARAMS_${PN}d = "defaults 80"

USERADD_PACKAGES = "${PN}d"
USERADD_PARAM_${PN}d = "--system --no-create-home --shell /bin/false \
                        --user-group nobody"

do_install_append() {
    install -d ${D}${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/atftpd.init ${D}${sysconfdir}/init.d/atftpd

    install -d ${D}/srv/tftp

    rm ${D}${sbindir}/in.tftpd
    
    install -d ${D}${systemd_unitdir}/system
    install -m 0644 ${WORKDIR}/atftpd.service ${D}${systemd_unitdir}/system
}

PACKAGES =+ "atftpd"

FILES_${PN} = "${bindir}/*"

FILES_${PN}d = "${sbindir}/* \
  ${sysconfdir}/init.d/* \
  /srv/tftp \
  ${systemd_unitdir}/system/atftpd.service \
"

SYSTEMD_PACKAGES = "${PN}d"
SYSTEMD_SERVICE_${PN}d = "atftpd.service"
RPROVIDES_${PN}d += "${PN}d-systemd"
RREPLACES_${PN}d += "${PN}d-systemd"
RCONFLICTS_${PN}d += "${PN}d-systemd"