blob: 926d8851d2a782f650843eacf873c5c7f83a089d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
SUMMARY = "Gnuplot is a portable command-line driven graphing utility"
DESCRIPTION = "Gnuplot is a portable command-line driven interactive datafile \
(text or binary) and function plotting utility."
HOMEPAGE = "http://www.gnuplot.info/"
SECTION = "console/scientific"
LICENSE = "gnuplot"
LIC_FILES_CHKSUM = "file://Copyright;md5=243a186fc2fd3b992125d60d5b1bab8f"
DEPENDS = "${BPN}-native virtual/libx11 gd readline"
inherit autotools features_check
# depends on virtual/libx11
REQUIRED_DISTRO_FEATURES = "x11"
SRC_URI = "${SOURCEFORGE_MIRROR}/gnuplot/${BP}.tar.gz;name=archive \
http://www.mneuroth.de/privat/zaurus/qtplot-0.2.tar.gz;name=qtplot \
file://gnuplot.desktop \
file://gnuplot.png \
"
SRC_URI_append_class-target = " \
file://0002-do-not-build-demos.patch \
file://0003-Use-native-tools-to-build-docs.patch \
file://0004-Add-configure-option-to-find-qt5-native-tools.patch \
"
SRC_URI[archive.md5sum] = "2df8767c7399bee57a96296d46b4d5fb"
SRC_URI[archive.sha256sum] = "60a6764ccf404a1668c140f11cc1f699290ab70daa1151bb58fed6139a28ac37"
SRC_URI[qtplot.md5sum] = "0a481885a496092c77eb4017540b5cf6"
SRC_URI[qtplot.sha256sum] = "6df317183ff62cc82f3dcf88207a267cd6478cb5147f55d7530c94f1ad5f4132"
# for building docs (they deserve it) we need *doc2* tools native
BBCLASSEXTEND = "native"
DEPENDS_class-native = "readline-native"
PACKAGECONFIG_class-native = ""
SRC_URI_append_class-native = "file://0001-reduce-build-to-conversion-tools-for-native-build.patch"
do_install_class-native() {
install -d ${D}${bindir}
install ${B}/docs/*doc* ${D}${bindir}
rm ${D}${bindir}/*.o
}
PACKAGECONFIG ??= "cairo"
PACKAGECONFIG[cairo] = "--with-cairo,--without-cairo,cairo pango"
PACKAGECONFIG[lua] = "--with-lua,--without-lua,lua"
PACKAGECONFIG[qt5] = "--with-qt --with-qt5nativesysroot=${STAGING_DIR_NATIVE},--without-qt,qtbase-native qtbase qtsvg qttools-native"
EXTRA_OECONF = "--with-readline=${STAGING_LIBDIR}/.. \
--without-tutorial \
--disable-wxwidgets"
do_compile_prepend() {
install -m 0644 ${WORKDIR}/qtplot-0.2/qtopia.trm ${S}/term/
}
do_install_append_class-target() {
install -d ${D}${datadir}/applications/
install -m 0644 ${WORKDIR}/gnuplot.desktop ${D}${datadir}/applications/
install -d ${D}${datadir}/pixmaps/
install -m 0644 ${WORKDIR}/gnuplot.png ${D}${datadir}/pixmaps/
}
PACKAGES =+ "${PN}-x11"
RPROVIDES_${PN}-dbg += "${PN}-x11-dbg"
DESCRIPTION_${PN}-x11 = "X11 display terminal for Gnuplot."
SECTION_${PN}-x11 = "x11/scientific"
FILES_${PN}-x11 = "${libexecdir} ${datadir}/applications ${datadir}/pixmaps ${libdir}/X11 "
FILES_${PN} += "${datadir}/texmf"
|
