blob: 142065fd07d357c42c6d4aae4750eca684fcf4c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
SUMMARY = "The SPIR-V Tools project provides an API and commands for \
processing SPIR-V modules"
DESCRIPTION = "The project includes an assembler, binary module parser, \
disassembler, validator, and optimizer for SPIR-V."
SECTION = "graphics"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
SRCREV = "b27b1afd12d05bf238ac7368bb49de73cd620a8e"
SRC_URI = "git://github.com/KhronosGroup/SPIRV-Tools.git"
UPSTREAM_CHECK_GITTAGREGEX = "^(?P<pver>\d+(\.\d+)+)$"
S = "${WORKDIR}/git"
inherit cmake python3native
DEPENDS = "spirv-headers"
EXTRA_OECMAKE += "-DSPIRV-Headers_SOURCE_DIR=${STAGING_EXECPREFIXDIR}"
do_install_append_class-target() {
# reproducibility: remove build host path
sed -i ${D}${libdir}/cmake/SPIRV-Tools/SPIRV-ToolsTarget.cmake \
-e 's:${STAGING_DIR_HOST}::g'
}
FILES_SOLIBSDEV = ""
FILES_${PN} += "${libdir}/*.so"
PACKAGES =+ "${PN}-lesspipe"
FILES_${PN}-lesspipe = "${base_bindir}/spirv-lesspipe.sh"
RDEPENDS_${PN}-lesspipe += "${PN} bash"
BBCLASSEXTEND = "native nativesdk"
|
