aboutsummaryrefslogtreecommitdiffstats
path: root/classes
diff options
context:
space:
mode:
authorRichard Purdie <rpurdie@rpsys.net>2006-11-14 22:29:46 +0000
committerRichard Purdie <rpurdie@rpsys.net>2006-11-14 22:29:46 +0000
commit0b152ed05c0cd22f440c00e44357b95d470ccbf0 (patch)
treec305fe962c0ecc7ef7145ce71f5bc465b3356a8a /classes
parentd6aa197a5f26cad7dd38b19aa6cd017898944f40 (diff)
downloadopenembedded-0b152ed05c0cd22f440c00e44357b95d470ccbf0.tar.gz
openembedded-0b152ed05c0cd22f440c00e44357b95d470ccbf0.tar.bz2
openembedded-0b152ed05c0cd22f440c00e44357b95d470ccbf0.zip
site infrastructure changes: Allow more than one file per target so common files can be created. Add a new class to handle this. Based on the work of Jamie Lenehan, with changes from me. This commit creates a common x86 file and the arm configs are merged but much work still remains.
Diffstat (limited to 'classes')
-rw-r--r--classes/base.bbclass5
-rw-r--r--classes/siteinfo.bbclass126
2 files changed, 131 insertions, 0 deletions
diff --git a/classes/base.bbclass b/classes/base.bbclass
index f4a0076f19..f3564bf285 100644
--- a/classes/base.bbclass
+++ b/classes/base.bbclass
@@ -694,6 +694,7 @@ python __anonymous () {
pn = bb.data.getVar('PN', d, 1)
+ # OBSOLETE in bitbake 1.7.4
srcdate = bb.data.getVar('SRCDATE_%s' % pn, d, 1)
if srcdate != None:
bb.data.setVar('SRCDATE', srcdate, d)
@@ -727,6 +728,10 @@ python () {
# Patch handling
inherit patch
+# Configuration data from site files
+# Move to autotools.bbclass?
+inherit siteinfo
+
EXPORT_FUNCTIONS do_clean do_mrproper do_fetch do_unpack do_configure do_compile do_install do_package do_populate_pkgs do_stage do_rebuild do_fetchall
MIRRORS[func] = "0"
diff --git a/classes/siteinfo.bbclass b/classes/siteinfo.bbclass
new file mode 100644
index 0000000000..5a37768b52
--- /dev/null
+++ b/classes/siteinfo.bbclass
@@ -0,0 +1,126 @@
+# This class exists to provide information about the targets that
+# may be needed by other classes and/or recipes. If you add a new
+# target this will probably need to be updated.
+
+#
+# Returns information about 'what' for the named target 'target'
+# where 'target' == "<arch>-<os>"
+#
+# 'what' can be one of
+# * target: Returns the target name ("<arch>-<os>")
+# * endianess: Return "be" for big endian targets, "le" for little endian
+# * bits: Returns the bit size of the target, either "32" or "64"
+# * libc: Returns the name of the c library used by the target
+#
+# It is an error for the target not to exist.
+# If 'what' doesn't exist then an empty value is returned
+#
+def get_siteinfo_list(d):
+ import bb
+
+ target = bb.data.getVar('HOST_ARCH', d, 1) + "-" + bb.data.getVar('HOST_OS', d, 1)
+
+ targetinfo = {\
+ "armeb-linux": "endian-big bit-32 common-glibc arm-common",\
+ "armeb-linux-uclibc": "endian-big bit-32 common-uclibc arm-common",\
+ "arm-linux": "endian-little bit-32 common-glibc arm-common",\
+ "arm-linux-gnueabi": "endian-little bit-32 common-glibc arm-common arm-linux",\
+ "arm-linux-uclibc": "endian-little bit-32 common-uclibc arm-common",\
+ "arm-linux-uclibcgnueabi": "endian-little bit-32 common-uclibc arm-common arm-linux-uclibc",\
+ "i386-linux": "endian-little bit-32 common-glibc ix86-common",\
+ "i486-linux": "endian-little bit-32 common-glibc ix86-common",\
+ "i586-linux": "endian-little bit-32 common-glibc ix86-common",\
+ "i686-linux": "endian-little bit-32 common-glibc ix86-common",\
+ "i386-linux-uclibc": "endian-little bit-32 common-uclibc ix86-common",\
+ "i486-linux-uclibc": "endian-little bit-32 common-uclibc ix86-common",\
+ "i586-linux-uclibc": "endian-little bit-32 common-uclibc ix86-common",\
+ "i686-linux-uclibc": "endian-little bit-32 common-uclibc ix86-common",\
+ "mipsel-linux": "endian-little bit-32 common-glibc",\
+ "mipsel-linux-uclibc": "endian-little bit-32 common-uclibc",\
+ "powerpc-darwin": "endian-big bit-32 common-darwin",\
+ "powerpc-linux": "endian-big bit-32 common-glibc",\
+ "powerpc-linux-uclibc": "endian-big bit-32 common-uclibc",\
+ "sh3-linux": "endian-little bit-32 common-glibc sh-common",\
+ "sh4-linux": "endian-little bit-32 common-glibc sh-common",\
+ "sh4-linux-uclibc": "endian-little bit-32 common-uclibc sh-common",\
+ "sparc-linux": "endian-big bit-32 common-glibc",\
+ "x86_64-linux": "endian-little bit-64 common-glibc",\
+ "x86_64-linux-uclibc": "endian-little bit-64 common-uclibc"}
+ if target in targetinfo:
+ info = targetinfo[target].split()
+ info.append(target)
+ return info
+ else:
+ bb.error("Information not available for target '%s'" % target)
+
+
+#
+# Define which site files to use. We check for several site files and
+# use each one that is found, based on the list returned by get_siteinfo_list()
+#
+# Search for the files in the following directories:
+# 1) ${BBPATH}/site (in reverse) - app specific, then site wide
+# 2) ${FILE_DIRNAME}/site-${PV} - app version specific
+#
+def siteinfo_get_files(d):
+ import bb, os
+
+ sitefiles = ""
+
+ # Determine which site files to look for
+ sites = get_siteinfo_list(d)
+ sites.append("common");
+
+ # Check along bbpath for site files and append in reverse order so
+ # the application specific sites files are last and system site
+ # files first.
+ path_bb = bb.data.getVar('BBPATH', d, 1)
+ for p in (path_bb or "").split(':'):
+ tmp = ""
+ for i in sites:
+ fname = os.path.join(p, 'site', i)
+ if os.path.exists(fname):
+ tmp += fname + " "
+ sitefiles = tmp + sitefiles;
+
+ # Now check for the applications version specific site files
+ path_pkgv = os.path.join(bb.data.getVar('FILE_DIRNAME', d, 1), "site-" + bb.data.getVar('PV', d, 1))
+ for i in sites:
+ fname = os.path.join(path_pkgv, i)
+ if os.path.exists(fname):
+ sitefiles += fname + " "
+
+ bb.note("SITE files " + sitefiles);
+ return sitefiles
+
+#
+# Export CONFIG_SITE to the enviroment. The autotools will make use
+# of this to determine where to load in variables from. This is a
+# space seperate list of shell scripts processed in the order listed.
+#
+export CONFIG_SITE = "${@siteinfo_get_files(d)}"
+
+
+def siteinfo_get_endianess(d):
+ info = get_siteinfo_list(d)
+ if 'endian-little' in info:
+ return "le"
+ elif 'endian-big' in info:
+ return "be"
+ bb.error("Site info could not determine endianess for target")
+
+def siteinfo_get_bits(d):
+ info = get_siteinfo_list(d)
+ if 'bit-32' in info:
+ return "32"
+ elif 'bit-64' in info:
+ return "64"
+ bb.error("Site info could not determine bit size for target")
+
+#
+# Make some information available via variables
+#
+SITEINFO_ENDIANESS = "${@siteinfo_get_endianess(d)}"
+SITEINFO_BITS = "${@siteinfo_get_bits(d)}"
+
+