10 files changed, 353 insertions, 0 deletions
diff --git a/recipes/db/db-native_4.2.52.bb b/recipes/db/db-native_4.2.52.bb
new file mode 100644
index 0000000000..0e6381bca1
--- /dev/null
+++ b/recipes/db/db-native_4.2.52.bb
@@ -0,0 +1,2 @@
+require db_${PV}.bb
+require db4-native.inc
diff --git a/recipes/db/db-native_4.3.29.bb b/recipes/db/db-native_4.3.29.bb
new file mode 100644
index 0000000000..0e6381bca1
--- /dev/null
+++ b/recipes/db/db-native_4.3.29.bb
@@ -0,0 +1,2 @@
+require db_${PV}.bb
+require db4-native.inc
diff --git a/recipes/db/db3-3.2.9/autofoo.patch b/recipes/db/db3-3.2.9/autofoo.patch
new file mode 100644
index 0000000000..d385b95722
--- /dev/null
+++ b/recipes/db/db3-3.2.9/autofoo.patch
@@ -0,0 +1,71 @@
+--- dist/Makefile.in	2000-11-30 17:07:33.000000000 -0600
++++ dist/Makefile.in	2004-09-01 19:47:37.000000000 -0500
+@@ -2,6 +2,7 @@
+ 
+ srcdir=	@srcdir@/..
+ builddir=.
++top_builddir=.
+ 
+ ##################################################
+ # C, C++
+--- dist/configure.in	2001-01-19 11:36:43.000000000 -0600
++++ dist/configure.in	2004-09-01 19:45:35.000000000 -0500
+@@ -38,7 +38,6 @@
+ AC_SUBST(LIBJSO_LIBS)
+ AC_SUBST(LIBS)
+ AC_SUBST(LIBSO_LIBS)
+-AC_SUBST(LIBTOOL)
+ AC_SUBST(LIBTSO_LIBS)
+ AC_SUBST(LIBXSO_LIBS)
+ AC_SUBST(MAKEFILE_CC)
+@@ -48,7 +47,6 @@
+ AC_SUBST(RPC_OBJS)
+ AC_SUBST(SOFLAGS)
+ AC_SUBST(SOLINK)
+-AC_SUBST(SOSUFFIX)
+ 
+ dnl $o is set to ".o" or ".lo", and is the file suffix used in the
+ dnl Makefile instead of .o
+@@ -205,27 +203,15 @@
+ dnl Dynamic library and libtool configuration; optional, but required for
+ dnl Tcl or Java support.
+ LIBDB_ARGS="libdb.a"
+-LIBTOOL="nolibtool"
+ POSTLINK="@true"
+-SOSUFFIX="so"
+ if test "$db_cv_dynamic" = "yes"; then
++	AM_PROG_LIBTOOL
+ 	SAVE_CC="${MAKEFILE_CC}"
+ 	SAVE_CXX="${MAKEFILE_CXX}"
+ 
+-	# Configure libtool.
+-	AC_MSG_CHECKING(libtool configuration)
+-	AC_MSG_RESULT([])
+-	${CONFIG_SHELL-/bin/sh} $srcdir/ltconfig \
+-		--no-verify $srcdir/ltmain.sh \
+-		--output=./libtool $host_os \
+-		--disable-static \
+-	|| AC_MSG_ERROR([libtool configure failed])
+-
+-	SOSUFFIX=`sed -e '/^library_names_spec=/!d' -e 's/.*\.\([[a-zA-Z0-9_]]*\).*/\1/' ./libtool`
+ 	DEFAULT_LIB="\$(libso_target)"
+ 	DEFAULT_INSTALL="install_dynamic"
+ 	LIBDB_ARGS="\$(libso_linkname)"
+-	LIBTOOL="\$(SHELL) ./libtool"
+ 
+ 	MAKEFILE_CC="\$(LIBTOOL) --mode=compile ${SAVE_CC}"
+ 	MAKEFILE_CXX="\$(LIBTOOL) --mode=compile ${SAVE_CXX}"
+@@ -373,13 +359,6 @@
+ AC_REPLACE_FUNCS(getcwd getopt memcmp memcpy memmove)
+ AC_REPLACE_FUNCS(raise snprintf strcasecmp strerror vsnprintf)
+ 
+-dnl XXX
+-dnl Nasty hack.  AC_REPLACE_FUNCS added entries of the form xxx.o to the
+-dnl LIBOBJS variable.  They have to be xxx.lo if we are building shared
+-dnl libraries.  Use sed, configure already requires it.
+-tmp="`echo \"$LIBOBJS\" | sed \"s/\.o/${o}/g\"`"
+-LIBOBJS="$tmp"
+-
+ dnl Check for system functions we optionally use.
+ AC_CHECK_FUNCS(getuid pstat_getdynamic sysconf sched_yield strtoul yield)
+ 
diff --git a/recipes/db/db3-native_3.2.9.bb b/recipes/db/db3-native_3.2.9.bb
new file mode 100644
index 0000000000..492f7407d1
--- /dev/null
+++ b/recipes/db/db3-native_3.2.9.bb
@@ -0,0 +1,8 @@
+SECTION = "libs"
+VIRTUAL_NAME = "virtual/db-native"
+CONFLICTS = "db-native"
+inherit native
+require db3_${PV}.bb
+
+FILESPATH = "${@base_set_filespath([ '${FILE_DIRNAME}/db3-${PV}', '${FILE_DIRNAME}/db3', '${FILE_DIRNAME}/files', '${FILE_DIRNAME}' ], d)}"
+PACKAGES = ""
diff --git a/recipes/db/db3_3.2.9.bb b/recipes/db/db3_3.2.9.bb
new file mode 100644
index 0000000000..872ceeab87
--- /dev/null
+++ b/recipes/db/db3_3.2.9.bb
@@ -0,0 +1,87 @@
+SECTION = "libs"
+DESCRIPTION = "Berkeley DB v3."
+HOMEPAGE = "http://www.oracle.com/technology/products/berkeley-db/db/index.html"
+LICENSE = "BSD"
+PR = "r3"
+VIRTUAL_NAME ?= "virtual/db"
+CONFLICTS = "db"
+
+# it doesn't make any sense to have multiple relational
+# databases on an embedded machine, virtual/db allows
+# a build to select the desired one.
+PROVIDES += "${VIRTUAL_NAME}"
+
+SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz \
+	   file://autofoo.patch;patch=1"
+S = "${WORKDIR}/db-${PV}/dist"
+B = "${WORKDIR}/db-${PV}/build_unix"
+
+inherit autotools
+
+EXTRA_OECONF = "--enable-shared --enable-compat185 --enable-static"
+EXTRA_OEMAKE = "'SHELL=/bin/sh' 'ar=`which ${AR}` cr' 'chmod=`which chmod`' \
+		'cp=`which cp`' 'ln=`which ln`' 'mkdir=`which mkdir`' 'ranlib=`which ${RANLIB}`' \
+		'rm=`which rm`' 'strip=`which ${STRIP}`'"
+
+PACKAGES = "${PN}-dbg ${PN} ${PN}-bin ${PN}-dev ${PN}-doc ${PN}-locale"
+
+FILES_${PN} = "${libdir}/libdb-3.2*so*"
+FILES_${PN}-bin = "${bindir}"
+FILES_${PN}-dev = "${includedir} ${libdir}/libdb.so ${libdir}/libdb.a \
+		   ${libdir}/libdb-3.so ${libdir}/libdb.la ${libdir}/libdb-3.2.a \
+		   ${libdir}/libdb-3.2.la"
+
+do_configure_prepend () {
+	set -e
+	(
+		cd ${S}
+		. ./RELEASE
+		(echo "AC_DEFUN(AM_VERSION_SET, [" &&
+		echo "AC_SUBST(DB_VERSION_MAJOR)" &&
+		echo "AC_DEFINE(DB_VERSION_MAJOR, [$DB_VERSION_MAJOR])" &&
+		echo "DB_VERSION_MAJOR=$DB_VERSION_MAJOR" &&
+		echo "AC_SUBST(DB_VERSION_MINOR)" &&
+		echo "AC_DEFINE(DB_VERSION_MINOR, [$DB_VERSION_MINOR])" &&
+		echo "DB_VERSION_MINOR=$DB_VERSION_MINOR" &&
+		echo "AC_SUBST(DB_VERSION_PATCH)" &&
+		echo "AC_DEFINE(DB_VERSION_PATCH, [$DB_VERSION_PATCH])" &&
+		echo "DB_VERSION_PATCH=$DB_VERSION_PATCH" &&
+		echo "AC_SUBST(DB_VERSION_STRING)" &&
+		echo "AC_DEFINE(DB_VERSION_STRING, [$DB_VERSION_STRING])" &&
+		echo "DB_VERSION_STRING=\"\\\"\$DB_VERSION_STRING\\\"\"" &&
+		echo "])dnl") > acinclude.m4
+	)
+}
+
+do_configure () {
+	rm -f ${S}/configure
+	autotools_do_configure
+}
+
+do_compile () {
+	oe_runmake
+}
+
+do_stage () {
+	install -m 0644 db_185.h ../include/db_cxx.h db.h ${STAGING_INCDIR}/
+	oe_libinstall -so -a libdb-3.2 ${STAGING_LIBDIR}
+	ln -sf libdb-3.2.so ${STAGING_LIBDIR}/libdb.so
+	ln -sf libdb-3.2.a ${STAGING_LIBDIR}/libdb.a
+}
+
+do_install () {
+	oe_runmake \
+		prefix=${D}${prefix} \
+		exec_prefix=${D}${exec_prefix} \
+		bindir=${D}${bindir} \
+		includedir=${D}${includedir} \
+		libdir=${D}${libdir} \
+		docdir=${D}${docdir} \
+		install
+}
+
+python do_package() {
+	if bb.data.getVar('DEBIAN_NAMES', d, 1):
+		bb.data.setVar('PKG_${PN}', 'libdb3', d)
+	bb.build.exec_func('package_do_package', d)
+}
diff --git a/recipes/db/db4-native.inc b/recipes/db/db4-native.inc
new file mode 100644
index 0000000000..cc83d86dd8
--- /dev/null
+++ b/recipes/db/db4-native.inc
@@ -0,0 +1,28 @@
+# This wrapper builds a native version of the Oracal
+# Berkeley DB for those packages which need it (e.g.
+# perl).
+
+VIRTUAL_NAME = "virtual/db-native"
+CONFLICTS = "db3-native"
+#PR tracks the non-native package
+
+inherit native
+
+do_package() {
+:
+}
+
+PACKAGES = ""
+
+do_stage() {
+         # The .h files get installed read-only, the autostage
+         # function just uses cp -pPR, so do this by hand
+         rm -rf ${STAGE_TEMP}
+         mkdir -p ${STAGE_TEMP}
+         oe_runmake DESTDIR="${STAGE_TEMP}" install_include
+         cp -pPRf ${STAGE_TEMP}/${includedir}/* ${STAGING_INCDIR}/.
+         rm -rf ${STAGE_TEMP}
+         oe_libinstall -so -C .libs libdb-${PVM} ${STAGING_LIBDIR}
+         ln -sf libdb-${PVM}.so ${STAGING_LIBDIR}/libdb.so
+         ln -sf libdb-${PVM}.a ${STAGING_LIBDIR}/libdb.a
+}
diff --git a/recipes/db/db4.inc b/recipes/db/db4.inc
new file mode 100644
index 0000000000..12d4ad2166
--- /dev/null
+++ b/recipes/db/db4.inc
@@ -0,0 +1,96 @@
+# Version 4 of the Berkeley DB from Oracle
+#
+# At present this package only installs the DB code
+# itself (shared libraries, .a in the dev package),
+# documentation and headers.
+#
+# The headers have the same names as those as v3
+# of the DB, only one version can be used *for dev*
+# at once - DB3 and DB4 can both be installed on the
+# same system at the same time if really necessary.
+
+
+DESCRIPTION = "Berkeley DB v4."
+HOMEPAGE = "http://www.oracle.com/technology/products/berkeley-db/db/index.html"
+SECTION = "libs"
+LICENSE = "BSD"
+VIRTUAL_NAME ?= "virtual/db"
+CONFLICTS = "db3"
+
+SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz"
+
+inherit autotools
+
+# Put virtual/db in any appropriate provider of a
+# relational database, use it as a dependency in
+# place of a specific db and use:
+#
+# PREFERRED_PROVIDER_virtual/db
+#
+# to select the correct db in the build (distro) .conf
+PROVIDES += "${VIRTUAL_NAME}"
+
+# bitbake isn't quite clever enough to deal with db,
+# the distribution sits in the expected directory, but all
+# the builds must occur from a sub-directory.  The following
+# persuades bitbake to go to the right place
+S = "${WORKDIR}/db-${PV}/dist"
+B = "${WORKDIR}/db-${PV}/build_unix"
+
+# The executables go in a separate package - typically there
+# is no need to install these unless doing real database
+# management on the system.
+PACKAGES += " ${PN}-bin"
+
+# Package contents
+FILES_${PN} = "${libdir}/libdb-4*so*"
+FILES_${PN}-bin = "${bindir}/*"
+# The dev package has the .so link (as in db3) and the .a's -
+# it is therefore incompatible (cannot be installed at the
+# same time) as the db3 package
+FILES_${PN}-dev = "${includedir} ${libdir}/*"
+
+EXTRA_OECONF = "${DB4_CONFIG}"
+
+# Override the MUTEX setting here, the POSIX library is
+# the default - "POSIX/pthreads/library".
+# Don't ignore the nice SWP instruction on the ARM:
+# These enable the ARM assembler mutex code, this won't
+# work with thumb compilation...
+ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
+MUTEX = ""
+MUTEX_arm = "${ARM_MUTEX}"
+MUTEX_armeb = "${ARM_MUTEX}"
+EXTRA_OECONF += "${MUTEX}"
+
+# Cancel the site stuff - it's set for db3 and destroys the
+# configure.
+CONFIG_SITE = ""
+do_configure() {
+	( cd ${WORKDIR}/db-${PV}/dist ; gnu-configize ) 
+	oe_runconf
+}
+
+
+do_install_append() {
+	# The docs end up in /usr/docs - not right.
+	if test -d "${D}/${prefix}/docs"
+	then
+		mkdir -p "${D}/${datadir}"
+		test ! -d "${D}/${docdir}" || rm -rf "${D}/${docdir}"
+		mv "${D}/${prefix}/docs" "${D}/${docdir}"
+	fi
+}
+
+do_stage() {
+	# The .h files get installed read-only, the autostage
+	# function just uses cp -pPR, so do this by hand
+	rm -rf ${STAGE_TEMP}
+	mkdir -p ${STAGE_TEMP}
+	oe_runmake DESTDIR="${STAGE_TEMP}" install_include
+	cp -pPRf ${STAGE_TEMP}/${includedir}/* ${STAGING_INCDIR}/.
+	rm -rf ${STAGE_TEMP}
+	oe_libinstall -so -C .libs libdb-${PVM} ${STAGING_LIBDIR}
+	ln -sf libdb-${PVM}.so ${STAGING_LIBDIR}/libdb.so
+	ln -sf libdb-${PVM}.a ${STAGING_LIBDIR}/libdb.a
+}
diff --git a/recipes/db/db_4.2.52.bb b/recipes/db/db_4.2.52.bb
new file mode 100644
index 0000000000..ae9591ddcb
--- /dev/null
+++ b/recipes/db/db_4.2.52.bb
@@ -0,0 +1,11 @@
+PR = "r8"
+
+#major version number
+PVM = "4.2"
+
+require db4.inc
+
+#TODO SRC_URI += "file://arm-thumb-mutex.patch;patch=1"
+
+#configuration - set in local.conf to override
+DB4_CONFIG ?= " --disable-cryptography --disable-queue --disable-replication --disable-verify --enable-hash"
diff --git a/recipes/db/db_4.3.29.bb b/recipes/db/db_4.3.29.bb
new file mode 100644
index 0000000000..d5733beb39
--- /dev/null
+++ b/recipes/db/db_4.3.29.bb
@@ -0,0 +1,12 @@
+PR = "r10"
+
+# major version number
+PVM = "4.3"
+
+require db4.inc
+
+SRC_URI += "file://arm-thumb-mutex.patch;patch=1"
+
+#configuration - set in local.conf to override
+# All the --disable-* options replace --enable-smallbuild, which breaks a bunch of stuff (eg. postfix)
+DB4_CONFIG ?= "--enable-o_direct --disable-cryptography --disable-queue --disable-replication --disable-statistics --disable-verify --enable-compat185"
diff --git a/recipes/db/files/arm-thumb-mutex.patch b/recipes/db/files/arm-thumb-mutex.patch
new file mode 100644
index 0000000000..acd446fcd8
--- /dev/null
+++ b/recipes/db/files/arm-thumb-mutex.patch
@@ -0,0 +1,36 @@
+--- db-4.3.29-dist/../dbinc/mutex.h	2005-11-15 07:33:27.761042518 -0800
++++ db-4.3.29-dist/../dbinc/mutex.h	2005-11-15 07:55:24.823920060 -0800
+@@ -470,6 +470,25 @@
+ #ifdef LOAD_ACTUAL_MUTEX_CODE
+ #define	MUTEX_SET_TEST	1		/* gcc/arm: 0 is clear, 1 is set. */
+ 
++#if defined __thumb__
++#define	MUTEX_SET(tsl) ({						\
++	int __r, __p;							\
++	asm volatile(							\
++		".align	2\n\t"						\
++		"bx	pc\n\t"						\
++		"nop\n\t"						\
++		".arm\n\t"						\
++		"swpb	%0, %2, [%3]\n\t"				\
++		"eor	%0, %0, #1\n\t"					\
++		"orr	%1, pc, #1\n\t"					\
++		"bx	%1\n\t"						\
++		".force_thumb"						\
++	    : "=&r" (__r), "=r" (__p)					\
++	    : "r" (1), "r" (tsl)					\
++	    );								\
++	__r & 1;							\
++})
++#else
+ #define	MUTEX_SET(tsl) ({						\
+ 	int __r;							\
+ 	asm volatile(							\
+@@ -480,6 +499,7 @@
+ 	    );								\
+ 	__r & 1;							\
+ })
++#endif
+ 
+ #define	MUTEX_UNSET(tsl)	(*(volatile tsl_t *)(tsl) = 0)
+ #define	MUTEX_INIT(tsl)		MUTEX_UNSET(tsl)