From ea8f2ca55df4194be0de9ad08c05c9dd33a7cbc1 Mon Sep 17 00:00:00 2001
From: Koen Kooi <koen@openembedded.org>
Date: Mon, 15 Aug 2005 17:41:04 +0000
Subject: Add pango 1.9.1

---
 packages/pango/pango_1.9.1.bb | 47 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 packages/pango/pango_1.9.1.bb

(limited to 'packages/pango')

diff --git a/packages/pango/pango_1.9.1.bb b/packages/pango/pango_1.9.1.bb
new file mode 100644
index 0000000000..bc7698c592
--- /dev/null
+++ b/packages/pango/pango_1.9.1.bb
@@ -0,0 +1,47 @@
+LICENSE = "LGPL"
+SECTION = "x11/libs"
+# Xt needed to keep autoconf's check for X11 happy
+DEPENDS = "glib-2.0 fontconfig freetype zlib x11 libxft xt gtk-doc"
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+PR = "r0"
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.7/pango-${PV}.tar.bz2 \
+	   file://no-tests.patch;patch=1"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glibtest \
+		--enable-explicit-deps=no \
+	        --disable-debug"
+
+FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
+
+LIBV = "1.4.0"
+
+do_stage () {
+	for lib in pango pangox pangoft2 pangoxft; do
+		oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
+	done
+	install -d ${STAGING_INCDIR}/pango
+	install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+python populate_packages_prepend () {
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+	do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}
-- 
cgit 1.2.3-korg