DESCRIPTION = "Plugins for GStreamer"
SECTION = "multimedia"
PRIORITY = "optional"
MAINTAINER = "Felix Domke <tmbinc@openembedded.org>"
DEPENDS = "gstreamer libcdio libmikmod libmad libogg tremor libvorbis libid3tag liboil alsa-lib neon flac"
PR = "r2"

inherit autotools pkgconfig

SRC_URI = "http://gstreamer.freedesktop.org/src/${PN}/${PN}-${PV}.tar.bz2"

EXTRA_OECONF = "--disable-x --disable-aalib --disable-esd --disable-shout2 \
		--disable-sdl --with-check=no --enable-neon"

acpaths = "-I ${S}/common/m4 -I ${S}/m4"

LIBV = "0.10"

python populate_packages_prepend () {
	gst_libdir = bb.data.expand('${libdir}/gstreamer-${LIBV}', d)
	postinst = bb.data.getVar('plugin_postinst', d, 1)

	do_split_packages(d, gst_libdir, '^libgst(.*)\.so$', 'gst-plugin-%s', 'GStreamer plugin for %s', postinst=postinst)
	do_split_packages(d, gst_libdir, '^libgst(.*)\.l?a$', 'gst-plugin-%s-dev', 'GStreamer plugin for %s (development files)')
}

do_configure_prepend() {
	for i in libtool ltoptions ltsugar ltversion lt~obsolete; do
		rm ${S}/m4/$i.m4 || /bin/true;
	done
}

do_stage() {
	autotools_stage_all
}

ALLOW_EMPTY = "1"