DESCRIPTION = "Paroli"
SECTION = "x11"
LICENSE = "GPL"
PV = "0.2.1+gitr${SRCREV}"
PR = "r27"

SRC_URI = "git://git.paroli-project.org/paroli.git;protocol=http"
S = "${WORKDIR}/git"

inherit distutils

PACKAGES += "${PN}-autostart ${PN}-theme ${PN}-sounds ${PN}-calculator"

RDEPENDS = "\
  python-datetime \
  python-subprocess \
  python-textutils \
  python-dbus \
  python-pygobject \
  python-elementary \
  dbus-x11 \
  task-fso-compliance \
  elementary \
  elementary-themes \
  edbus-ehal \
"

RDEPENDS_${PN}-calculator = "paroli"

E_CONFIG_DIR="/usr/share/enlightenment/data"

RULES_YAML = rules.yaml
RULES_YAML_om-gta01 = gta01_rules.yaml

do_configure_append() {
        echo "version=\"${SRCREV}\"" > ${S}/paroli-core/tichy/__version__.py
}

do_install_append() {
       	# install paroli theme
       	install -d ${D}${E_CONFIG_DIR}/themes
       	install ${S}/data/e-config/paroli.edj ${D}${E_CONFIG_DIR}/themes/
       	install ${S}/data/e-config/serenity.edj ${D}${E_CONFIG_DIR}/themes/
       	install -d ${D}${E_CONFIG_DIR}/config/paroli
       	install ${S}/data/e-config/paroli/* ${D}${E_CONFIG_DIR}/config/paroli/
       	install -d ${D}${E_CONFIG_DIR}/config/paroli-serenity
       	install ${S}/data/e-config/paroli-serenity/* ${D}${E_CONFIG_DIR}/config/paroli-serenity/
	install -d ${D}${datadir}/elementary/themes
	install ${S}/data/paroli.edj ${D}${datadir}/elementary/themes

    	install -d ${D}${datadir}/pixmaps	
	install ${S}/data/paroli.png ${D}${datadir}/pixmaps

       	# install autostart
    	install -d ${D}${E_CONFIG_DIR}/applications/all
	cp ${D}/usr/share/applications/paroli.desktop ${D}${E_CONFIG_DIR}/applications/all
    	install -d ${D}${E_CONFIG_DIR}/applications/startup
       	echo "${E_CONFIG_DIR}/applications/all/paroli.desktop" >> ${D}${E_CONFIG_DIR}/applications/startup/.order

	install -d ${D}${sysconfdir}/freesmartphone/oevents
	install ${S}/data/${RULES_YAML} ${D}${sysconfdir}/freesmartphone/oevents/paroli_rules.yaml
#	install ${S}/data/frameworkd.conf ${D}${sysconfdir}/paroli_frameworkd.conf

	install -d ${D}${sysconfdir}/freesmartphone/opreferences/conf/phone
	install ${S}/data/default.yaml ${D}${sysconfdir}/freesmartphone/opreferences/conf/phone/paroli_default.yaml

	install -d ${D}${datadir}/dbus-1/system-services/
	install ${S}/data/dbus/org.tichy.launcher.service ${D}${datadir}/dbus-1/system-services/

	install -d ${D}${datadir}/sounds
	install ${S}/data/sounds/* ${D}${datadir}/sounds

}

pkg_postinst_${PN}-autostart() {
#!/bin/sh
# do this off or on line
if [ "x$D" != "x" ]; then
	ROOTFS=${IMAGE_ROOTFS}
else
	ROOTFS=""
fi

# post installation script
if [ -x $ROOTFS${sysconfdir}/X11/Xsession.d/80zhone ]; then
   echo "*******************************************"
   echo "Deactivating zhone autostart"
   echo "*******************************************"
   chmod -x $ROOTFS${sysconfdir}/X11/Xsession.d/80zhone || true
fi
exit 0
}

pkg_postinst_${PN}() {
#!/bin/sh
# do this off or on line
if [ "x$D" != "x" ]; then
	ROOTFS=${IMAGE_ROOTFS}
else
	ROOTFS=""
fi
# post installation script
echo "*******************************************"
echo "Paroli post processing"
echo "*******************************************"
if [ ! -e $ROOTFS${sysconfdir}/freesmartphone/oevents/old_rules.yaml ] ; then
    echo "Backing up $ROOTFS${sysconfdir}/freesmartphone/oevents/rules.yaml"
    mv $ROOTFS${sysconfdir}/freesmartphone/oevents/rules.yaml $ROOTFS${sysconfdir}/freesmartphone/oevents/old_rules.yaml
fi
cp $ROOTFS${sysconfdir}/freesmartphone/oevents/paroli_rules.yaml $ROOTFS${sysconfdir}/freesmartphone/oevents/rules.yaml
exit 0
}

pkg_postinst_${PN}-sounds() {
#!/bin/sh
# do this off or on line
if [ "x$D" != "x" ]; then
	ROOTFS=${IMAGE_ROOTFS}
else
	ROOTFS=""
fi
# post installation script
if [ ! -e /$ROOTFS${sysconfdir}/freesmartphone/opreferences/conf/phone/old_default.yaml ] ; then
    echo "Backing up ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml"
    mv $ROOTFS${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml $ROOTFS${sysconfdir}/freesmartphone/opreferences/conf/phone/old_default.yaml
fi
cp $ROOTFS${sysconfdir}/freesmartphone/opreferences/conf/phone/paroli_default.yaml $ROOTFS${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml
exit 0
}

pkg_postinst_${PN}-theme() {
#!/bin/sh
# do this off or on line
if [ "x$D" != "x" ]; then
	ROOTFS=${IMAGE_ROOTFS}
else
	ROOTFS=""
fi
# post installation script
echo 'E_PROFILE="-profile paroli"' > $ROOTFS${sysconfdir}/enlightenment/default_profile
exit 0
}

FILES_${PN} += " \
	${sysconfdir}/dbus-1 \
	${sysconfdir}/paroli \
	${sysconfdir}/freesmartphone/oevents \
#	${sysconfdir}/paroli_frameworkd.conf \ 
	${datadir}/lib \
	${datadir}/bin \
	${datadir}/applications/common-for-edje \
	${datadir}/applications/i-o2 \
	${datadir}/applications/msgs2 \
	${datadir}/applications/paroli-launcher2 \
	${datadir}/applications/people2 \
	${datadir}/applications/settings \
	${datadir}/applications/tele2 \
	${datadir}/applications \
	${datadir}/elementary \
	${datadir}/paroli \
	${datadir}/pixmaps \
	${datadir}/dbus-1/system-services/ \
	"

FILES_${PN}-calculator += " \
	${datadir}/applications/calculator \
	"

FILES_${PN}-theme = " \
	${E_CONFIG_DIR}/themes \
	${E_CONFIG_DIR}/config \
	"

FILES_${PN}-autostart = "${E_CONFIG_DIR}/applications"

FILES_${PN}-sounds = " \
	${datadir}/sounds/ \
	${sysconfdir}/freesmartphone/opreferences/conf/phone/paroli_default.yaml \
	"

CONFFILES_${PN} += " \
	${sysconfdir}/paroli/paroli.cfg \
	${sysconfdir}/freesmartphone/oevents/paroli_rules.yaml \
	"
CONFFILES_${PN}-sounds += " \
	${sysconfdir}/freesmartphone/opreferences/conf/phone/paroli_default.yaml \
	"