blob: 6164737fa9929714c163a8c69acab6012c961b6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
DESCRIPTION = "Navit is a car navigation system with routing engine."
LICENSE = "GPL"
SECTION = "x11/applications"
DEPENDS = "glib-2.0 gtk+ qt4-x11-free gd gypsy librsvg-native"
RDEPENDS_${PN} = " navit-icons ${PN}-config "
RDEPENDS_${PN}_append_shr = " fsoraw"
RDEPENDS_${PN}-gui-qml = "qt4-plugin-imageformat-svg"
RRECOMMENDS_${PN} = "gpsd ${PN}-dbus ${PN}-speech-cmdline ${PN}-gui-internal ${PN}-graphics-gtk"
RSUGGESTS_${PN} = "flite espeak ${PN}-speech-dbus ${PN}-gui-gtk ${PN}-gui-qml ${PN}-graphics-sdl ${PN}-graphics-qt ${PN}-maptool"
PE = "1"
INC_PR = "r8"
inherit autotools gettext
EXTRA_OECONF += " \
--disable-binding-python \
--disable-samplemap \
--enable-avoid-unaligned \
--enable-graphics-qt-qpainter \
--enable-gui-qml \
--enable-svg2png-scaling-flag=32 \
--disable-speech-speech-dispatcher \
--enable-cache-size=20971520 \
"
# --enable-avoid-float \
#check for TARGET_FPU=soft and inform configure of the result so it can disable some floating points
require navit-fpu.inc
EXTRA_OECONF += "${@get_navit_fpu_setting(bb, d)}"
PACKAGES =+ "${PN}-maptool ${PN}-config ${PN}-dbus ${PN}-speech-cmdline ${PN}-speech-dbus ${PN}-gui-gtk ${PN}-gui-internal ${PN}-gui-qml ${PN}-graphics-sdl ${PN}-graphics-gtk ${PN}-graphics-qt"
EXTRA_AUTORECONF = " -I m4"
CONFFILES_${PN}-config += "${datadir}/navit/navit.default.xml \
${datadir}/navit/navit.xml \
${datadir}/navit/maps.xml \
${datadir}/navit/osd.xml \
${datadir}/navit/speech.xml \
${datadir}/navit/plugins.xml \
"
SRC_URI += "file://navit.xml \
file://maps.xml \
file://osd.xml \
file://speech.xml \
file://plugins.xml \
"
#Second launcher for shr
SRC_URI_append_shr = "file://navitD.png \
file://navit.launcher.sh \
"
FILES_${PN} += "${libdir}/${PN}/*/*.so"
FILES_${PN}-dbg += "${libdir}/${PN}/*/.debug"
FILES_${PN}-maptool = " ${bindir}/maptool "
FILES_${PN}-config = " ${datadir}/navit/*.xml "
FILES_${PN}-dbus = " ${datadir}/dbus-1/services/ ${libdir}/${PN}/binding/libbinding_dbus.so "
FILES_${PN}-speech-cmdline = " ${libdir}/${PN}/speech/libspeech_cmdline.so "
FILES_${PN}-speech-dbus = " ${libdir}/${PN}/speech/libspeech_dbus.so "
FILES_${PN}-gui-gtk = " ${libdir}/${PN}/gui/libgui_gtk.so "
FILES_${PN}-gui-qml = " ${libdir}/${PN}/gui/libgui_qml.so ${datadir}/navit/skins/ "
FILES_${PN}-gui-internal = " ${libdir}/${PN}/gui/libgui_internal.so "
FILES_${PN}-graphics-sdl = " ${libdir}/${PN}/graphics/libgraphics_sdl.so "
FILES_${PN}-graphics-qt = " ${libdir}/${PN}/graphics/libgraphics_qt_qpainter.so "
FILES_${PN}-graphics-gtk = " ${libdir}/${PN}/graphics/libgraphics_gtk_drawing_area.so "
do_configure_prepend() {
#Remove xpm building, replaced by icons in own package
sed -i 's/\(.*SUBDIRS.*\) xpm\( \|$\)\(.*\)/\1\2\3/g' ${S}/navit/Makefile.am
# MOC=`$PKG_CONFIG QtGui --variable=moc_location` returns only /usr/bin/moc4 which is not available on hosts without Qt
sed -i "s#MOC=#MOC=${STAGING_DIR_NATIVE}#g" ${S}/configure.in
}
do_install_append() {
install -d ${D}${datadir}/applications/
install -m 0644 ${S}/navit/xpm/desktop_icons/navit.desktop ${D}${datadir}/applications/
install -d ${D}${datadir}/pixmaps/
install -m 0644 ${S}/navit/xpm/desktop_icons/128x128/navit.png ${D}${datadir}/pixmaps/
# fix QA issue
sed -i 's#Categories=GTK;Utility;Geography;#Categories=Graphics;#g' ${D}${datadir}/applications/navit.desktop
rm ${D}${libdir}/${PN}/*/*.la
#Use split config
mv ${D}${datadir}/navit/navit.xml ${D}${datadir}/navit/navit.default.xml
install -m 0644 ${WORKDIR}/navit.xml ${D}${datadir}/navit/navit.xml
install -m 0644 ${WORKDIR}/maps.xml ${D}${datadir}/navit/maps.xml
install -m 0644 ${WORKDIR}/osd.xml ${D}${datadir}/navit/osd.xml
install -m 0644 ${WORKDIR}/speech.xml ${D}${datadir}/navit/speech.xml
install -m 0644 ${WORKDIR}/plugins.xml ${D}${datadir}/navit/plugins.xml
}
do_install_append_shr() {
# Install second launcher for shr
install -m 0644 ${S}/navit/xpm/desktop_icons/navit.desktop ${D}${datadir}/applications/navitD.desktop
install -m 0644 ${WORKDIR}/navitD.png ${D}${datadir}/pixmaps/navitD.png
install -m 0755 ${WORKDIR}/navit.launcher.sh ${D}${bindir}/
# Change .desktop files a bit
sed -i 's#Exec=navit#Exec=fsoraw -fr CPU,GPS -- navit.launcher.sh#g' ${D}${datadir}/applications/navit.desktop
sed -i 's#Exec=navit#Exec=fsoraw -fr CPU,GPS,Display -- navit.launcher.sh#g' ${D}${datadir}/applications/navitD.desktop
sed -i 's#Categories=GTK;Utility;Geography;#Categories=Graphics;#g' ${D}${datadir}/applications/navitD.desktop
sed -i 's#Comment=GPS Navigation#Comment=GPS Navigation Display blanking disabled#g' ${D}${datadir}/applications/navitD.desktop
sed -i 's#Icon=navit#Icon=navitD#g' ${D}${datadir}/applications/navitD.desktop
sed -i 's#Navit#NavitD#g' ${D}${datadir}/applications/navitD.desktop
}
|
