aboutsummaryrefslogtreecommitdiff
path: root/recipes/totem/totem_2.30.0.bb
blob: 5f869a457dcf19eb2bae31799d21af6ee6d29d2d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
# totem OE build file
# Copyright (C) 2004, Advanced Micro Devices, Inc.  All Rights Reserved
# Released under the MIT license (see packages/COPYING)

DESCRIPTION = "A GTK2 based media player"
HOMEPAGE = "http://www.gnome.org/projects/totem/"
LICENSE = "GPL"

DEPENDS = " nautilus tracker gnome-doc-utils libunique libgdata totem-pl-parser gtk+ dbus bluez-libs libglade gconf libxml2 gst-ffmpeg gst-plugins-bad  gst-plugins-base" 
RDEPENDS_${PN} += "iso-codes"
RRECOMMENDS_${PN} += "gst-plugin-playbin \
                      gst-plugin-gconfelements \
		      gst-plugin-decodebin \
		      gst-plugin-decodebin2 \
		      gst-ffmpeg \
		      gst-plugin-audioresample \
		      gst-plugin-ximagesink \
		      gst-plugin-xvimagesink \
		      gst-plugin-alsa \
		      gst-plugin-avi \
		      gst-plugin-ffmpegcolorspace \
		      gst-plugin-flv \
		      gst-plugin-nuvdemux \
		      gst-plugin-videoscale \
		      gst-plugin-a52dec \
		      gst-plugin-mpegaudioparse \
		      gst-plugin-ossaudio \
		      gst-plugin-pulse \
		      gst-plugin-autodetect \
		      totem-plugin-thumbnail totem-plugin-dbus "

inherit gnome

PR = "r1"

SRC_URI += "file://gst-detect.diff"

SRC_URI[archive.md5sum] = "ecee18e876f6adf5845f71ace87549ca"
SRC_URI[archive.sha256sum] = "9d8edd266bd2546e4c8034de1196b79855e24a3634d05cc4f8a07fd3edc7b1af"

EXTRA_OECONF=" --enable-shared \
           --disable-static \
           --disable-schemas-install \
	       --disable-iso-codes \
	       --disable-debug \
           --enable-browser-plugins \
	       --disable-run-in-source-tree \
	       --disable-vala \
	       --enable-python \
           --with-dbus \
	       "

do_configure_prepend() {
    sed -i -e s:help::g ${S}/Makefile.am
    sed -i \
        -e s:'`$PKG_CONFIG --variable defsdir pygobject-2.0`':\"${STAGING_DATADIR}/pygobject/2.0/defs\":g \
        -e s:'`$PKG_CONFIG --variable=defsdir pygtk-2.0`':\"${STAGING_DATADIR}/pygtk/2.0/defs\":g \
        -e s:'`$PKG_CONFIG --variable=pygtkincludedir pygobject-2.0`':\"${STAGING_INCDIR}/pygtk-2.0\":g \
        -e s:'`$PKG_CONFIG --variable=datadir pygobject-2.0`':\"${STAGING_DATADIR}\":g \
        -e s:'`$PKG_CONFIG --variable codegendir pygobject-2.0`':\"${STAGING_DATADIR}/pygobject/2.0/codegen\":g \
        -e s:'`$PKG_CONFIG --variable=codegendir pygtk-2.0`':\"${STAGING_DATADIR}/pygobject/2.0/codegen\":g \
        -e s:'`$PKG_CONFIG --variable=fixxref pygobject-2.0`':\"${STAGING_DATADIR}/pygobject/xsl/fixxref.py\":g \
        -e 's:PYTHON_CFLAGS="-I$PY_PREFIX/include/python$PYTHON_VERSION":PYTHON_CFLAGS="-I${STAGING_INCDIR}/python$PYTHON_VERSION":g' \
        ${S}/configure.in
}

PACKAGES_DYNAMIC += " totem-plugin-* "

python populate_packages_prepend () {
	totem_libdir = bb.data.expand('${libdir}/totem/plugins/', d)

	do_split_packages(d, totem_libdir, '^(.*)', 'totem-plugin-%s', 'totem plugin for %s', allow_dirs=True, extra_depends='')
}

FILES_${PN} = "${bindir}/* ${sysconfdir} ${libdir}/lib*.so.* ${libexecdir} ${datadir}/icons ${datadir}/totem ${datadir}/applications \
"

RDEPENDS_totem-plugin-iplayer_append = "python-pygtk gst-plugin-flv"
RDEPENDS_totem-plugin-youtube_append = "python-pygtk gnome-vfs-plugin-http gst-plugin-gnomevfs gst-plugin-flv"


PACKAGES =+ "totem-nautilus-extension totem-browser-plugin-dbg totem-browser-plugin"

FILES_${PN}-dbg += "${libdir}/totem/plugins/*/.debug"
FILES_${PN}-dev += "${libdir}/totem/plugins/*/*a"
FILES_totem-browser-plugin-dbg += "${libdir}/mozilla/plugins/.debug"
FILES_totem-browser-plugin += "${libdir}/mozilla/plugins/"

FILES_totem-nautilus-extension += "${libdir}/nautilus/extensions-2.0/*.so"