aboutsummaryrefslogtreecommitdiffstats
path: root/recipes/xapian/xapian-bindings-python_1.0.14.bb
blob: 0208bfee6f0f0b2226d5d922b51ca97785232886 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
DESCRIPTION = "Open Source Search Engine Library python bindings"
HOMEPAGE = "http://xapian.org"
SECTION = "devel/libs"
PRIORITY = "optional"
LICENSE = "GPL"
DEPENDS = "xapian-core xapian-core-native"
PR = "r0"

SRC_URI = "http://www.oligarchy.co.uk/xapian/${PV}/xapian-bindings-${PV}.tar.gz"

S = "${WORKDIR}/xapian-bindings-${PV}"

inherit autotools pkgconfig distutils-base

export XAPIAN_CONFIG = "${STAGING_BINDIR_NATIVE}/xapian-config"

EXTRA_OECONF = "--with-python --without-php --without-ruby --without-tcl \
                --without-csharp --without-java"

do_configure () {
        BUILD_SYS=${BUILD_SYS} HOST_SYS=${MULTIMACH_HOST_SYS} \
        autotools_do_configure
}

# we don't want make to generate pyc and pyo files, but make install
# expects them later
do_compile() {
        oe_runmake PYTHON=true
        touch ${S}/python/xapian.pyc
        touch ${S}/python/xapian.pyo
}

# workaround for bad installation destination and removal of fake .py? files
do_install_append() {
        mv ${D}/${STAGING_DIR_HOST}/usr/* ${D}/usr/
        rm ${D}/${PYTHON_SITEPACKAGES_DIR}/xapian.py?
}

SRC_URI[md5sum] = "d6f86ccc3d1a534902e1cf8df1cb43f3"
SRC_URI[sha256sum] = "05072405fd182425d90374d2d5b69c36fe9fd927f44e397c449a9bdd1a971218"