summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb
diff options
context:
space:
mode:
authorAnuj Mittal <anuj.mittal@intel.com>2021-01-20 10:34:49 +0800
committerAnuj Mittal <anuj.mittal@intel.com>2021-01-20 11:09:52 +0800
commite54cc195087126707b0e2ca70f66d25c8537d02b (patch)
treecf0324114d7d8960931172c26454a22ffb3becb4 /meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb
parent48f732fe4adb972e143a11f52d5d01ed98f0874b (diff)
downloadopenembedded-core-contrib-anujm/wip.tar.gz
openembedded-core-contrib-anujm/wip.tar.bz2
openembedded-core-contrib-anujm/wip.zip
meson: upgrade 0.56.0 -> 0.56.2anujm/wip
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Diffstat (limited to 'meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb')
-rw-r--r--meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb66
1 files changed, 66 insertions, 0 deletions
diff --git a/meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb b/meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb
new file mode 100644
index 0000000000..7fdc4c86d9
--- /dev/null
+++ b/meta/recipes-devtools/meson/nativesdk-meson_0.56.2.bb
@@ -0,0 +1,66 @@
+include meson.inc
+
+inherit nativesdk
+inherit siteinfo
+
+SRC_URI += "file://meson-setup.py \
+ file://meson-wrapper"
+
+def meson_endian(prefix, d):
+ arch, os = d.getVar(prefix + "_ARCH"), d.getVar(prefix + "_OS")
+ sitedata = siteinfo_data_for_machine(arch, os, d)
+ if "endian-little" in sitedata:
+ return "little"
+ elif "endian-big" in sitedata:
+ return "big"
+ else:
+ bb.fatal("Cannot determine endianism for %s-%s" % (arch, os))
+
+# The cross file logic is similar but not identical to that in meson.bbclass,
+# since it's generating for an SDK rather than a cross-compile. Important
+# differences are:
+# - We can't set vars like CC, CXX, etc. yet because they will be filled in with
+# real paths by meson-setup.sh when the SDK is extracted.
+# - Some overrides aren't needed, since the SDK injects paths that take care of
+# them.
+do_install_append() {
+ install -d ${D}${datadir}/meson
+ cat >${D}${datadir}/meson/meson.cross.template <<EOF
+[binaries]
+c = @CC
+cpp = @CXX
+ar = @AR
+nm = @NM
+strip = @STRIP
+pkgconfig = 'pkg-config'
+
+[properties]
+needs_exe_wrapper = true
+c_args = @CFLAGS
+c_link_args = @LDFLAGS
+cpp_args = @CPPFLAGS
+cpp_link_args = @LDFLAGS
+sys_root = @OECORE_TARGET_SYSROOT
+
+[host_machine]
+system = '${SDK_OS}'
+cpu_family = '${SDK_ARCH}'
+cpu = '${SDK_ARCH}'
+endian = '${@meson_endian("SDK", d)}'
+EOF
+
+ install -d ${D}${SDKPATHNATIVE}/post-relocate-setup.d
+ install -m 0755 ${WORKDIR}/meson-setup.py ${D}${SDKPATHNATIVE}/post-relocate-setup.d/
+
+ # We need to wrap the real meson with a thin env setup wrapper.
+ mv ${D}${bindir}/meson ${D}${bindir}/meson.real
+ install -m 0755 ${WORKDIR}/meson-wrapper ${D}${bindir}/meson
+}
+
+RDEPENDS_${PN} += "\
+ nativesdk-ninja \
+ nativesdk-python3 \
+ nativesdk-python3-setuptools \
+ "
+
+FILES_${PN} += "${datadir}/meson ${SDKPATHNATIVE}"