libinput: upgrade 1.21.0 -> 1.22.0

Changelog:
==========
 CI: prettify the include of templates
 CI: remove one occurrence of fedora instead of distro.name
 CI: make freebsd slightly more in line with others
 CI: remove unused test
 CI: do not retry the qemu runs
 CI: rely on b2c to start qemu tests
 CI: include systemd-udev in the fedora image
 CI: start a full systemd environment before running the testsuite
 CI: in b2c, compile on the host, then test in qemu
 quirks: update quirks for Lenovo IdeaPad Duet 3
 quirks: add Lenovo Legion 7 keyboard
 libwacom: fix warnings building without libwacom
 tablet: check libevdev_get_abs_info() return value
 tablet: avoid errors calling libevdev_get_abs_info()
 meson.build: always set HAVE_GTK_WAYLAND
 tools: hide debug-gui help when building with -Ddebug-gui=false
 debug-gui: avoid locking pointer twice
 util: use ck_assert_ptr_eq() instead of ck_assert_ptr_null()
 touchpad: add escape and asterisk to the DWT blacklist
 libinput 1.22.0
 quirks: add quirks for Acer Spin 513 (Lazor)
 quirks: add generic quirks for ARM based chromebooks
 quirks: add volume rocker quirk for Lenovo IdeaPad Duet 3i
 quirks: Add quirks for Surface Laptop Studio touchpad
 quirks: Add quirks to improve tablet-mode on the Surface Laptop Studio
 gitlab CI: drop the manual meson to junit conversion
 meson.build: drop listing of header files from compilation targets
 meson.build: fix build without Wayland
 gitlab CI: dnf remove gtk4-devel for the no-debug-gui deps job
 CODING_STYLE: update with a better description for variable assignments
 evdev: fix a tab vs space indentation issue
 doc/user: minor rewording of the pointer accel profile list
 gitlab ci: drop EOL'd ubuntu 21.10
 tools: add missing dwtp option setting
 evdev: remove duplicate "device is a switch" message
 gitlab-ci: export MESON_TESTTHREADS so meson actually sees it
 gitlab-ci: explicitly call "meson setup" to improve readability
 gitlab-ci: add commandline options to the meson-build.sh script
 CI: drop the job count for the valgrind test suite to 2
 filter: a few whitespace fixes and extra comments
 filter: fix the mix of normalized vs device coordinates
 filter: remove an unnecessary layer of indirection
 filter: constify the tracker API
 filter: localize a few variables
 evdev: rename post_trackpoint_scroll to post_button_scroll
 filter: constify the interfaces and make them static
 filter: don't normalize the const filter approach
 evdev: use filter_dispatch_constant() for button scrolling
 evdev: use filter_dispatch_constant() for the lenovo trackpoint "wheel"
 filter: don't normalize the speed again in the default mouse filter
 filter: apply the same factor for constant motion as for normal motion
 filter: add a flat trackpoint accel
 gitlab CI: don't install valgrind, it's already in the template
 gitlab CI: update freebsd to 13.1
 gitlab CI: pre-install all packages we need
 Fix Framework quirk so it wirks with 12 gen intel
 util: return the number of elements from strv_from_string
 meson: use install_emptydir to create directory
 test: exclude the two high-delay debounce tests from the valgrind CI run

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>

1 files changed, 50 insertions, 0 deletions

diff --git a/meta/recipes-graphics/wayland/libinput_1.22.0.bb b/meta/recipes-graphics/wayland/libinput_1.22.0.bb
new file mode 100644
index 0000000000..5a5fc9f35d
--- /dev/null
+++ b/meta/recipes-graphics/wayland/libinput_1.22.0.bb
@@ -0,0 +1,50 @@
+SUMMARY = "Library to handle input devices in Wayland compositors"
+DESCRIPTION = "libinput is a library to handle input devices in Wayland \
+compositors and to provide a generic X.Org input driver. It provides \
+device detection, device handling, input device event processing and \
+abstraction so minimize the amount of custom input code compositors need to \
+provide the common set of functionality that users expect."
+HOMEPAGE = "http://www.freedesktop.org/wiki/Software/libinput/"
+SECTION = "libs"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=bab4ac7dc1c10bc0fb037dc76c46ef8a"
+
+DEPENDS = "libevdev udev mtdev libcheck"
+
+SRC_URI = "git://gitlab.freedesktop.org/libinput/libinput.git;protocol=https;branch=main \
+           file://run-ptest \
+           file://determinism.patch \
+           "
+SRCREV = "fc59e574e050c502c9a3adefacf97babf3d09c7a"
+S = "${WORKDIR}/git"
+
+UPSTREAM_CHECK_REGEX = "libinput-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
+
+inherit meson pkgconfig lib_package ptest
+
+# Patch out build directory, otherwise it leaks into ptest binary
+do_configure:append() {
+    sed -i -e "s,${WORKDIR},,g" config.h
+    if [ -e "litest-config.h" ]; then
+        sed -i -e "s,${WORKDIR},,g" litest-config.h
+    fi
+}
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[libwacom] = "-Dlibwacom=true,-Dlibwacom=false,libwacom"
+PACKAGECONFIG[gui] = "-Ddebug-gui=true,-Ddebug-gui=false,cairo gtk+3"
+
+UDEVDIR = "`pkg-config --variable=udevdir udev`"
+
+EXTRA_OEMESON += "-Dudev-dir=${UDEVDIR} \
+                  -Ddocumentation=false \
+                  ${@bb.utils.contains('PTEST_ENABLED', '1', '-Dtests=true -Dinstall-tests=true', '-Dtests=false -Dinstall-tests=false', d)} \
+                  -Dzshcompletiondir=no"
+
+# package name changed in 1.8.1 upgrade: make sure package upgrades work
+RPROVIDES:${PN} = "libinput"
+RREPLACES:${PN} = "libinput"
+RCONFLICTS:${PN} = "libinput"
+
+FILES:${PN}-ptest += "${libexecdir}/libinput/libinput-test-suite"